chromeos/components/media_app_ui/resources/js/BUILD.gn

# Copyright 2019 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//chromeos/components/web_applications/system_apps.gni")
import("//third_party/closure_compiler/compile_js.gni")

media_closure_flags = system_app_closure_flags_strict + [ "hide_warnings_for=chromeos/components/media_app_ui/media_app_ui.mojom-lite-for-compile.js" ]

group("closure_compile") {
  deps = [
    ":closure_compile_app",
    ":closure_compile_index",
  ]
}

js_type_check("closure_compile_index") {
  closure_flags = media_closure_flags
  deps = [
    ":app_context_test_support",
    ":launch",
    ":mojo_api_bootstrap",
  ]
}

js_type_check("closure_compile_app") {
  closure_flags =
      media_closure_flags + ignore_load_time_data_errors_closure_flags
  deps = [ ":receiver" ]
}

js_library("app_context_test_support") {
}

js_library("launch") {
  externs_list = [
    "//chromeos/components/web_applications/externs/file_handling.externs.js",
    "dom_draft.externs.js",

    # The privileged context can't access the app, but shares struct definitions
    # passed over postMessage.
    "media_app.externs.js",
  ]
  deps = [
    ":error_reporter",
    ":message_types",
    ":mojo_api_bootstrap",
    "//chromeos/components/system_apps/public/js:message_pipe",
  ]
}

js_library("message_types") {
}

js_library("error_reporter") {
  externs_list = [ "$externs_path/crash_report_private.js" ]
}

js_library("piex_module_loader") {
}

js_library("piex_module") {
  deps = [ "//ui/file_manager/image_loader:piex_loader" ]
}

js_library("receiver") {
  externs_list = [ "media_app.externs.js" ]
  deps = [
    ":message_types",
    ":piex_module",
    ":piex_module_loader",
    "//chromeos/components/system_apps/public/js:message_pipe",
    "//ui/webui/resources/js:load_time_data",
  ]
}

js_library("mojo_api_bootstrap") {
  deps = [
    "//chromeos/components/media_app_ui:mojo_bindings_js_library_for_compile",
  ]
}