chromeos/startup/BUILD.gn

# Copyright 2018 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")

component("startup") {
  output_name = "chromeos_startup"
  defines = [ "IS_CHROMEOS_STARTUP_IMPL" ]
  public_deps = [ "//chromeos/crosapi/mojom" ]
  deps = [
    ":constants",
    "//base",
  ]
  sources = [
    "startup.cc",
    "startup.h",
  ]

  if (is_chromeos_lacros) {
    sources += [
      "browser_init_params.cc",
      "browser_init_params.h",
      "browser_params_proxy.cc",
      "browser_params_proxy.h",
      "browser_postlogin_params.cc",
      "browser_postlogin_params.h",
    ]
  }
}

component("constants") {
  output_name = "chromeos_startup_constants"
  defines = [ "IS_CHROMEOS_STARTUP_CONSTANTS_IMPL" ]
  deps = [ "//base" ]
  sources = [
    "startup_switches.cc",
    "startup_switches.h",
  ]
}

source_set("unit_tests") {
  testonly = true
  deps = [
    ":constants",
    ":startup",
    "//base",
    "//base/test:test_support",
    "//testing/gtest",
  ]
  sources = [ "startup_unittest.cc" ]
}