services/service_manager/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//testing/test.gni")

group("all") {
  testonly = true
  deps = [
    ":service_manager",
  ]

  if (!is_ios) {
    deps += [
      # These tests heavily rely on service binaries, which are not supported on
      # iOS.
      "//services/service_manager/tests",
    ]
  }
}

source_set("service_manager") {
  sources = [
    "background_service_manager.cc",
    "background_service_manager.h",
    "connect_params.cc",
    "connect_params.h",
    "service_manager.cc",
    "service_manager.h",
    "service_process_launcher_delegate.h",
    "service_process_launcher_factory.h",
    "switches.cc",
    "switches.h",
  ]

  configs += [ "//build/config/compiler:wexit_time_destructors" ]

  deps = [
    "//base/third_party/dynamic_annotations",
  ]

  public_deps = [
    "//base",
    "//mojo/public/cpp/bindings",
    "//services/catalog:constants",
    "//services/catalog:lib",
    "//services/catalog/public/mojom:constants",
    "//services/service_manager/public/cpp",
    "//services/service_manager/public/mojom",
    "//services/service_manager/sandbox",
  ]

  if (!is_ios) {
    sources += [
      "service_process_launcher.cc",
      "service_process_launcher.h",
    ]

    deps += [
      "//mojo/core/embedder",
      "//services/service_manager/public/cpp/service_executable:switches",
    ]
  }

  if (is_linux) {
    deps += [ "//sandbox/linux:sandbox_services" ]
  }
}