third_party/WebKit/Source/core/probe/BUILD.gn

# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/WebKit/Source/core/core.gni")

action("instrumentation_probes") {
  script = "../../build/scripts/make_instrumenting_probes.py"

  inputs = [
    "CoreProbes.pidl",
    "CoreProbes.json5",
    "../../build/scripts/templates/InstrumentingProbesImpl.cpp.tmpl",
    "../../build/scripts/templates/InstrumentingProbesInl.h.tmpl",
    "../../build/scripts/templates/ProbeSink.h.tmpl",
  ]

  outputs = [
    "$blink_core_output_dir/CoreProbesInl.h",
    "$blink_core_output_dir/CoreProbesImpl.cpp",
    "$blink_core_output_dir/CoreProbeSink.h",
  ]

  args = [
    rebase_path(inputs[0], root_build_dir),
    "--config",
    rebase_path("CoreProbes.json5", root_build_dir),
    "--output_dir",
    rebase_path(blink_core_output_dir, root_build_dir),
  ]
}

source_set("generated") {
  deps = [
    ":instrumentation_probes",
  ]
}

# Compiles the sources generated above.
blink_core_sources("probe") {
  sources = [
    "CoreProbes.cpp",
    "CoreProbes.h",
  ]
  sources += get_target_outputs(":instrumentation_probes")

  deps = [
    ":instrumentation_probes",
    "//skia",
    "//third_party/WebKit/Source/bindings/core/v8:bindings_core_v8_generated",
    "//third_party/WebKit/Source/core:all_generators",
    "//third_party/WebKit/Source/platform:make_platform_generated",
    "//third_party/WebKit/Source/platform/wtf",
    "//v8",
  ]
}