chromecast/media/cma/BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//chromecast/chromecast.gni")
import("//testing/test.gni")

# Targets may depend on this to bring in every CMA component.
group("cma") {
  public_deps = [
    "//chromecast/media/cma/backend",
    "//chromecast/media/cma/base",
    "//chromecast/media/cma/pipeline",
  ]
}

cast_source_set("test_support") {
  testonly = true
  sources = [
    "test/frame_generator_for_test.cc",
    "test/frame_generator_for_test.h",
    "test/frame_segmenter_for_test.cc",
    "test/frame_segmenter_for_test.h",
    "test/mock_cma_backend.cc",
    "test/mock_cma_backend.h",
    "test/mock_cma_backend_factory.cc",
    "test/mock_cma_backend_factory.h",
    "test/mock_frame_consumer.cc",
    "test/mock_frame_consumer.h",
    "test/mock_frame_provider.cc",
    "test/mock_frame_provider.h",
    "test/mock_multiroom_manager.h",
  ]

  deps = [
    "//base",
    "//chromecast/common/mojom",
    "//chromecast/media/cma/backend",
    "//chromecast/media/cma/base",
    "//media:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//ui/gfx/geometry",
  ]

  if (!enable_video_with_mixed_audio) {
    deps += [ "//chromecast/media/cma/backend:null_video" ]
  }
}

cast_source_set("unittests") {
  testonly = true
  sources = [
    "backend/audio_video_pipeline_device_unittest.cc",
    "base/balanced_media_task_runner_unittest.cc",
    "base/buffering_controller_unittest.cc",
    "base/buffering_frame_provider_unittest.cc",
    "base/decoder_buffer_adapter_unittest.cc",
    "base/demuxer_stream_adapter_unittest.cc",
    "base/demuxer_stream_for_test.cc",
    "base/demuxer_stream_for_test.h",
    "base/multi_demuxer_stream_adapter_unittest.cc",
    "pipeline/audio_video_pipeline_impl_unittest.cc",
  ]

  deps = [
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//chromecast/base",
    "//chromecast/media",
    "//chromecast/media:libcast_media",
    "//media",
    "//testing/gmock",
    "//testing/gtest",
  ]

  if (enable_video_with_mixed_audio) {
    defines = [ "ENABLE_VIDEO_WITH_MIXED_AUDIO" ]

    # libvideodecoderformixer is linked here for the
    # VideoDecoderForMixer::InitializeGraphicsForTesting symbol. Currently only
    # alsa platforms do anything useful in this initialization, so otherwise
    # just link in a dummy.
    if (use_alsa) {
      libs = [ "videodecoderformixer" ]
    } else {
      sources += [ "backend/dummy_initialize_graphics_for_testing.cc" ]
    }
  }

  data = [
    "//media/test/data/",
  ]

  # MultizoneBackendTest verifies rendering delay reported by the backend.
  if (supports_multizone) {
    sources += [ "backend/multizone_backend_unittest.cc" ]
  }
}