chrome/android/features/autofill_assistant/BUILD.gn

# Copyright 2019 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/config.gni")
import("//build/config/android/rules.gni")
import("//chrome/common/features.gni")

# The animated_poodle_java target is overridden downstream and used
# instead of this one if the enable_chrome_android_internal flag is
# enabled.
android_library("animated_poodle_java") {
  deps = [
    ":animated_poodle_resources",
  ]

  classpath_deps = [
    "//base:base_java",
    "//chrome/android:chrome_java",
    "//third_party/android_deps:android_support_v7_appcompat_java",
  ]

  java_files = [ "java/src/org/chromium/chrome/browser/" +
                 "autofill_assistant/header/AnimatedPoodle.java" ]
}

android_resources("animated_poodle_resources") {
  resource_dirs = [ "java/res_poodle" ]
  custom_package = "org.chromium.chrome.autofill_assistant.poodle"
}

android_library("java") {
  deps = [
    ":java_resources",
  ]

  classpath_deps = [
    "//base:base_java",
    "//chrome/android:chrome_java",
    "//components/signin/core/browser/android:java",
    "//components/url_formatter/android:url_formatter_java",
    "//components/policy/android:policy_java",
    "//content/public/android:content_java",
    "//mojo/public/java:bindings_java",
    "//third_party/android_deps:android_arch_lifecycle_common_java",
    "//third_party/android_deps:android_arch_lifecycle_runtime_java",
    "//third_party/android_deps:android_support_v7_appcompat_java",
    "//third_party/android_deps:com_android_support_design_java",
    "//third_party/android_deps:com_android_support_gridlayout_v7_java",
    "//third_party/android_deps:com_android_support_recyclerview_v7_java",
    "//third_party/android_deps:com_android_support_support_annotations_java",
    "//third_party/android_deps:com_android_support_support_compat_java",
    "//third_party/android_deps:com_android_support_support_core_ui_java",
    "//third_party/android_deps:com_android_support_support_core_utils_java",
    "//third_party/blink/public/mojom:android_mojo_bindings_java",
    "//ui/android:ui_java",
  ]

  if (enable_chrome_android_internal) {
    # TODO(crbug/951489): Change below to 'deps' once crbug/951489 is fixed.
    classpath_deps +=
        [ "//clank/features/autofill_assistant:animated_poodle_java" ]
  } else {
    classpath_deps += [ ":animated_poodle_java" ]
  }

  java_files = [
    "java/src/org/chromium/chrome/browser/autofill_assistant/AbstractListObserver.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantBottomBarCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantKeyboardCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantOnboardingCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantPeekHeightCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantSnackbar.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantUiController.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantClient.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantModuleEntryFactoryImpl.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/EditDistance.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/SizeListenableLinearLayout.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantActionsCarouselCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantActionsDecoration.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantCarouselCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantCarouselModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantChip.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantChipViewHolder.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/AssistantSuggestionsCarouselCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/carousel/ButtonView.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetails.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetailsCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetailsModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetailsViewBinder.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/ImageClickthroughData.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/header/AnimatedProgressBar.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/header/AssistantHeaderCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/header/AssistantHeaderModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/header/AssistantHeaderViewBinder.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBox.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBoxCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBoxModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBoxViewBinder.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayDelegate.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayDrawable.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayEventFilter.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantChoiceList.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestBinder.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestContactDetailsSection.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestCoordinator.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestDelegate.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestPaymentMethodSection.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestSection.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestShippingAddressSection.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestTermsSection.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantVerticalExpander.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantVerticalExpanderAccordion.java",
  ]
}

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/chrome/browser/autofill_assistant/AssistantModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantClient.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantUiController.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetails.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/details/AssistantDetailsModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/header/AssistantHeaderModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBox.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/infobox/AssistantInfoBoxModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayDelegate.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/overlay/AssistantOverlayModel.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestDelegate.java",
    "java/src/org/chromium/chrome/browser/autofill_assistant/payment/AssistantPaymentRequestModel.java",
  ]
  jni_package = "autofill_assistant"
}

android_library("test_java") {
  testonly = true

  java_files = [
    "javatests/src/org/chromium/chrome/browser/autofill_assistant/AutofillAssistantUiTest.java",
    "javatests/src/org/chromium/chrome/browser/autofill_assistant/EditDistanceTest.java",
  ]

  deps = [
    ":animated_poodle_java",
    ":java",
    "//base:base_java",
    "//base:base_java_test_support",
    "//chrome/android:chrome_java",
    "//chrome/android:chrome_test_util_java",
    "//content/public/test/android:content_java_test_support",
    "//net/android:net_java_test_support",
    "//third_party/android_deps:com_android_support_recyclerview_v7_java",
    "//third_party/android_support_test_runner:runner_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/android:ui_full_java",
  ]
}

android_resources("java_resources") {
  resource_dirs = [ "java/res" ]
  deps = [
    ":java_strings_grd",
    "//chrome/android:chrome_app_java_resources",
  ]
  custom_package = "org.chromium.chrome.autofill_assistant"
}

java_strings_grd("java_strings_grd") {
  defines = chrome_grit_defines
  grd_file = "java/strings/android_chrome_autofill_assistant_strings.grd"
  outputs = [
    "values/android_chrome_autofill_assistant_strings.xml",
    "values-am/android_chrome_autofill_assistant_strings.xml",
    "values-ar/android_chrome_autofill_assistant_strings.xml",
    "values-bg/android_chrome_autofill_assistant_strings.xml",
    "values-bn/android_chrome_autofill_assistant_strings.xml",
    "values-ca/android_chrome_autofill_assistant_strings.xml",
    "values-cs/android_chrome_autofill_assistant_strings.xml",
    "values-da/android_chrome_autofill_assistant_strings.xml",
    "values-de/android_chrome_autofill_assistant_strings.xml",
    "values-el/android_chrome_autofill_assistant_strings.xml",
    "values-en-rGB/android_chrome_autofill_assistant_strings.xml",
    "values-es/android_chrome_autofill_assistant_strings.xml",
    "values-es-rUS/android_chrome_autofill_assistant_strings.xml",
    "values-et/android_chrome_autofill_assistant_strings.xml",
    "values-fa/android_chrome_autofill_assistant_strings.xml",
    "values-fi/android_chrome_autofill_assistant_strings.xml",
    "values-fr/android_chrome_autofill_assistant_strings.xml",
    "values-gu/android_chrome_autofill_assistant_strings.xml",
    "values-hi/android_chrome_autofill_assistant_strings.xml",
    "values-hr/android_chrome_autofill_assistant_strings.xml",
    "values-hu/android_chrome_autofill_assistant_strings.xml",
    "values-in/android_chrome_autofill_assistant_strings.xml",
    "values-it/android_chrome_autofill_assistant_strings.xml",
    "values-iw/android_chrome_autofill_assistant_strings.xml",
    "values-ja/android_chrome_autofill_assistant_strings.xml",
    "values-kn/android_chrome_autofill_assistant_strings.xml",
    "values-ko/android_chrome_autofill_assistant_strings.xml",
    "values-lt/android_chrome_autofill_assistant_strings.xml",
    "values-lv/android_chrome_autofill_assistant_strings.xml",
    "values-ml/android_chrome_autofill_assistant_strings.xml",
    "values-mr/android_chrome_autofill_assistant_strings.xml",
    "values-ms/android_chrome_autofill_assistant_strings.xml",
    "values-nb/android_chrome_autofill_assistant_strings.xml",
    "values-nl/android_chrome_autofill_assistant_strings.xml",
    "values-pl/android_chrome_autofill_assistant_strings.xml",
    "values-pt-rBR/android_chrome_autofill_assistant_strings.xml",
    "values-pt-rPT/android_chrome_autofill_assistant_strings.xml",
    "values-ro/android_chrome_autofill_assistant_strings.xml",
    "values-ru/android_chrome_autofill_assistant_strings.xml",
    "values-sk/android_chrome_autofill_assistant_strings.xml",
    "values-sl/android_chrome_autofill_assistant_strings.xml",
    "values-sr/android_chrome_autofill_assistant_strings.xml",
    "values-sv/android_chrome_autofill_assistant_strings.xml",
    "values-sw/android_chrome_autofill_assistant_strings.xml",
    "values-ta/android_chrome_autofill_assistant_strings.xml",
    "values-te/android_chrome_autofill_assistant_strings.xml",
    "values-th/android_chrome_autofill_assistant_strings.xml",
    "values-tl/android_chrome_autofill_assistant_strings.xml",
    "values-tr/android_chrome_autofill_assistant_strings.xml",
    "values-uk/android_chrome_autofill_assistant_strings.xml",
    "values-vi/android_chrome_autofill_assistant_strings.xml",
    "values-zh-rCN/android_chrome_autofill_assistant_strings.xml",
    "values-zh-rTW/android_chrome_autofill_assistant_strings.xml",
  ]
}