build/toolchain/goma.gni

# Copyright (c) 2013 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Defines the configuration of Goma.

declare_args() {
  # Set to true to enable distributed compilation using Goma.
  use_goma = false

  # This flag is for ChromeOS compiler wrapper.
  # By passing gomacc path via cmd-line arg, ChromeOS' compiler wrapper
  # invokes gomacc inside it.
  needs_gomacc_path_arg = false

  # Set the default value based on the platform.
  if (host_os == "win") {
    # Absolute directory containing the gomacc.exe binary.
    goma_dir = "C:\src\goma\goma-win64"
  } else {
    if (getenv("GOMA_DIR") != "") {
      # Absolute directory containing the gomacc binary.
      goma_dir = getenv("GOMA_DIR")
    } else {
      # Absolute directory containing the gomacc binary.
      goma_dir = getenv("HOME") + "/goma"
    }
  }
}

declare_args() {
  # TODO(crbug.com/726475): true if use_goma = true in the future.
  use_java_goma = false

  # Auto-configure for Goma RBE backend.
  # TODO(crbug.com/1015730): true if use_goma = true in the future.
  ios_use_goma_rbe = false
}

assert(!is_win || !use_goma || is_clang,
       "cl.exe does not work on goma, use clang")