ios/chrome/browser/incognito_reauth/ui_bundled/BUILD.gn

# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/build/chrome_build.gni")

source_set("incognito_reauth_commands") {
  sources = [ "incognito_reauth_commands.h" ]
  frameworks = [ "UIKit.framework" ]
}

source_set("incognito_reauth_util") {
  sources = [
    "incognito_reauth_util.h",
    "incognito_reauth_util.mm",
  ]
  deps = [
    "//ios/chrome/app/strings",
    "//ui/base",
  ]
  frameworks = [
    "UIKit.framework",
    "LocalAuthentication.framework",
  ]
}

source_set("ui") {
  sources = [
    "incognito_reauth_consumer.h",
    "incognito_reauth_view.h",
    "incognito_reauth_view.mm",
    "incognito_reauth_view_label.h",
    "incognito_reauth_view_label.mm",
  ]
  deps = [
    ":incognito_reauth_util",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/shared/ui/symbols",
    "//ios/chrome/common/ui/util",
    "//ui/base",
  ]
  frameworks = [ "UIKit.framework" ]
}

source_set("incognito_reauth_scene_agent") {
  sources = [
    "incognito_reauth_mediator.h",
    "incognito_reauth_mediator.mm",
    "incognito_reauth_scene_agent.h",
    "incognito_reauth_scene_agent.mm",
  ]
  deps = [
    ":incognito_reauth_commands",
    ":incognito_reauth_util",
    ":ui",
    "//base",
    "//components/pref_registry",
    "//components/prefs",
    "//components/prefs/ios",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/shared/coordinator/scene:observing_scene_agent",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/common/ui/reauthentication",
    "//ios/web/public",
    "//ui/base",
  ]
  frameworks = [ "UIKit.framework" ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "incognito_reauth_scene_agent_unittest.mm" ]
  deps = [
    ":incognito_reauth_scene_agent",
    "//base",
    "//base/test:test_support",
    "//components/prefs:test_support",
    "//ios/chrome/browser/browser_view/ui_bundled",
    "//ios/chrome/browser/shared/coordinator/scene/test",
    "//ios/chrome/browser/shared/model/browser",
    "//ios/chrome/browser/shared/model/browser/test:test_support",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile/test",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/model/web_state_list:web_state_list",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/common/ui/reauthentication",
    "//ios/chrome/test:block_cleanup_test",
    "//ios/web/public/test",
    "//testing/gtest",
    "//third_party/ocmock",
  ]
}
source_set("eg2_tests") {
  configs += [ "//build/config/ios:xctest_config" ]
  testonly = true

  sources = [ "incognito_reauth_egtest.mm" ]
  deps = [
    ":incognito_reauth_util",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/test:eg_test_support+eg2",
    "//ios/chrome/test/earl_grey:eg_test_support+eg2",
    "//ios/testing/earl_grey:eg_test_support+eg2",
    "//ui/base",
  ]
}