blob: de05018cc87c240cf33a35111ad41da53cb44989 [file] [log] [blame]
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
# Keep in sync with targets in remoting/remoting_client.gypi.
import("//build/config/features.gni")
import("//remoting/webapp/build_template.gni")
import("//remoting/webapp/files.gni")
group("webapp") {
deps = [
":webapp_v1",
":ar_sample_app",
":credits",
":ar_shared_module",
]
if (enable_internal_app_remoting_targets) {
deps += [ "//remoting/internal:ar_internal_apps" ]
}
if (enable_nacl) {
deps += [ ":webapp_v2" ]
}
}
# GYP version: remoting/remoting_client:remoting_credits
action("credits") {
about_credits_file = "$target_gen_dir/credits.html"
script = "//tools/licenses.py"
inputs = [
"base/html/credits.tmpl",
"base/html/credits_entry.tmpl",
]
outputs = [
about_credits_file,
]
args = [
"credits",
rebase_path(about_credits_file, root_build_dir),
"--file-template",
rebase_path("base/html/credits.tmpl", root_build_dir),
"--entry-template",
rebase_path("base/html/credits_entry.tmpl", root_build_dir),
]
}
desktop_remoting_webapp("webapp_v1") {
webapp_type = "v1"
output_dir = "remoting/remoting-webapp"
zip_path = "remoting/remoting-webapp.zip"
extra_files = []
}
desktop_remoting_webapp("webapp_v2") {
webapp_type = "v2_pnacl"
output_dir = "remoting/remoting-webapp.v2"
zip_path = "remoting/remoting-webapp.v2.zip"
extra_files = [
"crd/remoting_client_pnacl.nmf.jinja2",
# TODO(garykac): Get correct path to this.
#"<(PRODUCT_DIR)/remoting_client_plugin_newlib.pexe",
]
}
app_remoting_webapp("ar_sample_app") {
app_key = "Sample_App"
app_id = "ljacajndfccfgnfohlgkdphmbnpkjflk"
app_client_id = "sample_client_id"
app_vendor = ""
app_name = "sample_app"
app_fullname = "App Remoting Client"
app_description = "App Remoting client"
app_capabilities = [ "GOOGLE_DRIVE" ]
manifest_key = "remotingdevbuild"
}
app_remoting_shared_module("ar_shared_module") {
#app_client_id = "sample_client_id"
app_name = "shared_module"
}
# GYP version: remoting/remoting_tests.gypi:remoting_browser_test_resources
copy("browser_test_resources") {
sources = remoting_webapp_browsertest_main_html_extra_files
outputs = [
"$root_out_dir/remoting/browser_test_resources/{{source_file_part}}",
]
}
remoting_unit_test_out_dir = "$root_out_dir/remoting/unittests"
group("unit_tests") {
data_deps = [
":blanketjs",
":js_files",
":qunit",
":sinonjs",
]
}
copy("js_files") {
# This list corresponds to webapp_js_files in remoting_webapp_unittests
# target in GYP.
sources = remoting_webapp_unittest_html_all_js_files +
remoting_webapp_wcs_sandbox_html_js_files +
remoting_webapp_background_html_js_files +
remoting_webapp_unittests_all_files
outputs = [
"$remoting_unit_test_out_dir/{{source_file_part}}",
]
}
copy("blanketjs") {
sources = [
"//third_party/blanketjs/src/blanket.js",
"//third_party/blanketjs/src/qunit_adapter.js",
]
outputs = [
"$remoting_unit_test_out_dir/blanketjs/{{source_file_part}}",
]
}
copy("sinonjs") {
sources = [
"//third_party/sinonjs/src/sinon-qunit.js",
"//third_party/sinonjs/src/sinon.js",
]
outputs = [
"$remoting_unit_test_out_dir/sinonjs/{{source_file_part}}",
]
}
copy("qunit") {
sources = [
"//third_party/qunit/src/browser_test_harness.js",
"//third_party/qunit/src/qunit.css",
"//third_party/qunit/src/qunit.js",
]
outputs = [
"$remoting_unit_test_out_dir/qunit/{{source_file_part}}",
]
}