chrome/credential_provider/setup/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/allocator.gni")
import("//build/config/clang/clang.gni")
import("//build/config/compiler/compiler.gni")
import("//build/config/dcheck_always_on.gni")
import("//build/nocompile.gni")
import("//chrome/process_version_rc_template.gni")
import("//testing/libfuzzer/fuzzer_test.gni")
import("//testing/test.gni")
import("//tools/grit/grit_rule.gni")

process_version_rc_template("version") {
  template_file = "gcp_setup.rc.version"
  output = "$root_out_dir/gcp_setup_version.rc"
}

source_set("common") {
  sources = [
    "setup_lib.cc",
    "setup_lib.h",
  ]
  public_deps = [
    "//base:base",
  ]
  deps = [
    ":version",
    "../gaiacp:common",
    "//chrome/installer/util:with_no_strings",
  ]
}

grit("setup_resources") {
  source = "gcp_setup_resources.grd"
  inputs = [
    "gcp_icon.ico",
  ]
  outputs = [
    "grit/gcp_setup_resources.h",
    "grit/gcp_setup_resources.rc",
  ]
  resource_ids = ""
  grit_flags = [
    "-E",
    "root_gen_dir=" + rebase_path(root_gen_dir, root_build_dir),
  ]
}

# Builds a self extracting 7-zip binary using the 7-zip SFX sources but with
# the credential provider's version resources.
executable("gcp_sfx") {
  deps = [
    ":setup_resources",
    ":version",
    "//third_party/lzma_sdk/Util/SfxSetup:7zS2_source",
  ]
  configs += [ "//build/config/win:windowed" ]
}

executable("gcp_setup") {
  sources = [
    "gcp_installer_crash_reporting.cc",
    "gcp_installer_crash_reporting.h",
    "setup.cc",
  ]
  deps = [
    ":common",
    ":setup_resources",
    "../eventlog:gcp_eventlog_messages",
    "../gaiacp:common",
    "//chrome/common:version_header",
    "//components/crash/content/app:app",
    "//components/crash/content/app:crash_export_thunks",
    "//components/crash/content/app:run_as_crashpad_handler",
    "//components/crash/core/common",
    "//content/public/common:static_switches",
  ]
  configs += [ "//build/config/win:windowed" ]
}