components/services/filesystem/BUILD.gn

# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//testing/test.gni")

static_library("lib") {
  sources = [
    "directory_impl.cc",
    "directory_impl.h",
    "shared_temp_dir.cc",
    "shared_temp_dir.h",
    "util.cc",
    "util.h",
  ]

  deps = [
    "//base",
    "//components/services/filesystem/public/mojom",
    "//mojo/public/cpp/system",
    "//url",
  ]
}

if (!is_ios) {
  source_set("test_support") {
    testonly = true

    sources = [
      "directory_test_helper.cc",
      "directory_test_helper.h",
    ]

    deps = [ "//base/test:test_support" ]

    public_deps = [
      ":lib",
      "//base",
      "//components/services/filesystem/public/mojom",
    ]
  }

  test("filesystem_service_unittests") {
    sources = [ "directory_impl_unittest.cc" ]

    deps = [
      ":lib",
      ":test_support",
      "//base",
      "//base/test:test_support",
      "//components/services/filesystem/public/mojom",
      "//mojo/core/test:run_all_unittests",
      "//mojo/public/cpp/bindings",
      "//mojo/public/cpp/system",
      "//testing/gtest",
    ]
  }
}