remoting/host/input_monitor/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//remoting/build/config/remoting_build.gni")

source_set("input_monitor") {
  public = [
    "local_input_monitor.h",
  ]

  sources = [
    "local_hotkey_input_monitor.h",
    "local_hotkey_input_monitor_chromeos.cc",
    "local_hotkey_input_monitor_mac.mm",
    "local_hotkey_input_monitor_win.cc",
    "local_hotkey_input_monitor_x11.cc",
    "local_input_monitor.cc",
    "local_input_monitor_win.cc",
    "local_input_monitor_win.h",
    "local_keyboard_input_monitor.h",
    "local_keyboard_input_monitor_chromeos.cc",
    "local_keyboard_input_monitor_mac.mm",
    "local_keyboard_input_monitor_win.cc",
    "local_keyboard_input_monitor_x11.cc",
    "local_mouse_input_monitor.h",
    "local_mouse_input_monitor_chromeos.cc",
    "local_mouse_input_monitor_mac.mm",
    "local_mouse_input_monitor_win.cc",
    "local_mouse_input_monitor_x11.cc",
  ]

  deps = [
    "//remoting/proto",
    "//third_party/webrtc/modules/desktop_capture",
  ]

  if (use_ozone) {
    deps += [ "//ui/ozone" ]
  }

  if (is_mac) {
    deps += [ "//third_party/google_toolbox_for_mac" ]
  }

  if (!use_x11 || (is_chromeos && !use_ozone)) {
    sources -= [
      "local_hotkey_input_monitor_x11.cc",
      "local_keyboard_input_monitor_x11.cc",
      "local_mouse_input_monitor_x11.cc",
    ]
  }
}