blob: 3765877589c1a4c5bea317202830ee9517e38e1b [file] [log] [blame]
# Copyright 2019 The ChromiumOS Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//common-mk/pkg_config.gni")
group("host") {
deps = [
"//vm_tools/cicerone:cicerone_client",
"//vm_tools/cicerone:vm_cicerone",
"//vm_tools/concierge",
"//vm_tools/maitred:maitred_client",
"//vm_tools/seneschal",
"//vm_tools/seneschal:seneschal_client",
"//vm_tools/syslog:vmlog_forwarder",
"//vm_tools/vsh",
"//vm_tools/vsh:vshd",
]
if (use.arcvm) {
deps += [ "//vm_tools/pstore_dump:vm_pstore_dump" ]
}
if (use.test) {
deps += [
"//vm_tools/cicerone:cicerone_test",
"//vm_tools/concierge:concierge_test",
"//vm_tools/syslog:syslog_forwarder_test",
"//vm_tools/vsh:vsh_test",
]
if (use.arcvm) {
deps += [ "//vm_tools/pstore_dump:vm_pstore_dump_test" ]
}
}
if (use.fuzzer) {
deps += [
"//vm_tools/cicerone:cicerone_container_listener_fuzzer",
"//vm_tools/vsh:vsh_client_fuzzer",
]
}
}
# D-Bus bindings from other platform2 projects need to be listed here so that
# the system include paths for the headers are added through pkg-config.
pkg_config("host_target_defaults_pkgs") {
pkg_deps = [
"libbrillo",
"libchrome",
"libcros_config",
"libnet-base",
"libpatchpanel-client",
]
}
config("host_target_defaults") {
configs = [ ":host_target_defaults_pkgs" ]
defines = [
"USE_BIG_GL=${use.libglvnd}",
"USE_BOREALIS_HOST=${use.borealis_host}",
"USE_CROSVM_CROSS_DOMAIN_CONTEXT=${use.cross_domain_context}",
"USE_CROSVM_CROSS_DOMAIN_CONTEXT_BOREALIS=${use.cross_domain_context_borealis}",
"USE_CROSVM_FIXED_BLOB_MAPPING=${use.crosvm_fixed_blob_mapping}",
"USE_CROSVM_VENUS_GWP_ASAN=${use.venus_gwp_asan}",
"USE_CROSVM_VIRTGPU_NATIVE_CONTEXT=${use.virtgpu_native_context}",
"USE_CROSVM_VIRTIO_VIDEO=${use.crosvm_virtio_video}",
"USE_CROSVM_VIRTIO_VIDEO_VD=${use.crosvm_virtio_video_vd}",
"USE_CROSVM_VULKAN=${use.vulkan}",
"USE_PMEM_DEVICE_FOR_ROOTFS=${use.amd64}",
]
}
if (use.fuzzer) {
pkg_config("vm_host_tools_fuzzer_pkg_deps") {
pkg_deps = [
"libprotobuf-mutator",
"protobuf",
"vm_protos",
]
}
}