content/common/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")
import("//build/config/ui.gni")
import("//media/media_options.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//tools/ipc_fuzzer/ipc_fuzzer.gni")
if (is_mac) {
  import("//build/config/mac/mac_sdk.gni")
}

source_set("common") {
  # Targets external to content should always link to the public API.
  # In addition, targets outside of the content component (shell and tests)
  # must not link to this because it will duplicate the code in the component
  # build.
  visibility = [ "//content/*" ]

  sources = [
    "accessibility_messages.h",
    "all_messages.h",
    "android/address_parser.cc",
    "android/address_parser.h",
    "android/address_parser_internal.cc",
    "android/address_parser_internal.h",
    "android/common_jni_registrar.cc",
    "android/common_jni_registrar.h",
    "android/gin_java_bridge_errors.cc",
    "android/gin_java_bridge_errors.h",
    "android/gin_java_bridge_value.cc",
    "android/gin_java_bridge_value.h",
    "android/hash_set.cc",
    "android/hash_set.h",
    "android/media_metadata_android.cc",
    "android/media_metadata_android.h",
    "android/resource_request_body_android.cc",
    "android/resource_request_body_android.h",
    "android/sync_compositor_messages.cc",
    "android/sync_compositor_messages.h",
    "android/sync_compositor_statics.cc",
    "android/sync_compositor_statics.h",
    "appcache_interfaces.cc",
    "appcache_interfaces.h",
    "appcache_messages.h",
    "ax_content_node_data.cc",
    "ax_content_node_data.h",
    "bluetooth/web_bluetooth_device_id.cc",
    "bluetooth/web_bluetooth_device_id.h",
    "browser_plugin/browser_plugin_constants.cc",
    "browser_plugin/browser_plugin_constants.h",
    "browser_plugin/browser_plugin_messages.h",
    "cache_storage/cache_storage_messages.h",
    "cache_storage/cache_storage_types.cc",
    "cache_storage/cache_storage_types.h",
    "child_process_host_impl.cc",
    "child_process_host_impl.h",
    "child_process_messages.h",
    "child_process_sandbox_support_impl_linux.cc",
    "child_process_sandbox_support_impl_linux.h",
    "child_process_sandbox_support_impl_shm_linux.cc",
    "clipboard_format.h",
    "clipboard_messages.h",
    "content_constants_internal.cc",
    "content_constants_internal.h",
    "content_export.h",
    "content_ipc_logging.cc",
    "content_message_generator.cc",
    "content_message_generator.h",
    "content_param_traits.cc",
    "content_param_traits.h",
    "content_param_traits_macros.h",
    "content_paths.cc",
    "content_security_policy_header.h",
    "content_switches_internal.cc",
    "content_switches_internal.h",
    "cross_site_document_classifier.cc",
    "cross_site_document_classifier.h",
    "cursors/webcursor.cc",
    "cursors/webcursor.h",
    "cursors/webcursor_android.cc",
    "cursors/webcursor_aura.cc",
    "cursors/webcursor_aurawin.cc",
    "cursors/webcursor_aurax11.cc",
    "cursors/webcursor_mac.mm",
    "cursors/webcursor_ozone.cc",
    "database_messages.h",
    "date_time_suggestion.h",
    "device_sensors/device_light_data.h",
    "device_sensors/device_light_hardware_buffer.h",
    "device_sensors/device_motion_hardware_buffer.h",
    "device_sensors/device_orientation_hardware_buffer.h",
    "devtools_messages.h",
    "discardable_shared_memory_heap.cc",
    "discardable_shared_memory_heap.h",
    "dom_storage/dom_storage_map.cc",
    "dom_storage/dom_storage_map.h",
    "dom_storage/dom_storage_messages.h",
    "drag_event_source_info.h",
    "drag_messages.h",
    "drag_traits.h",
    "dwrite_font_proxy_messages.h",
    "edit_command.h",
    "establish_channel_params.cc",
    "establish_channel_params.h",
    "file_utilities_messages.h",
    "fileapi/file_system_messages.h",
    "font_cache_dispatcher_win.cc",
    "font_cache_dispatcher_win.h",
    "font_config_ipc_linux.cc",
    "font_config_ipc_linux.h",
    "font_list.cc",
    "font_list.h",
    "font_list_android.cc",
    "font_list_fontconfig.cc",
    "font_list_mac.mm",
    "font_list_win.cc",
    "frame_message_enums.h",
    "frame_messages.h",
    "frame_owner_properties.cc",
    "frame_owner_properties.h",
    "frame_replication_state.cc",
    "frame_replication_state.h",
    "gamepad_hardware_buffer.h",
    "gamepad_messages.h",
    "gamepad_param_traits.cc",
    "gamepad_param_traits.h",
    "generic_shared_memory_id_generator.cc",
    "generic_shared_memory_id_generator.h",
    "gin_java_bridge_messages.h",
    "gpu/client/command_buffer_metrics.cc",
    "gpu/client/command_buffer_metrics.h",
    "gpu/client/context_provider_command_buffer.cc",
    "gpu/client/context_provider_command_buffer.h",
    "gpu_host_messages.h",
    "host_discardable_shared_memory_manager.cc",
    "host_discardable_shared_memory_manager.h",
    "host_shared_bitmap_manager.cc",
    "host_shared_bitmap_manager.h",
    "in_process_child_thread_params.cc",
    "in_process_child_thread_params.h",
    "indexed_db/indexed_db_constants.h",
    "indexed_db/indexed_db_key.cc",
    "indexed_db/indexed_db_key.h",
    "indexed_db/indexed_db_key_path.cc",
    "indexed_db/indexed_db_key_path.h",
    "indexed_db/indexed_db_key_range.cc",
    "indexed_db/indexed_db_key_range.h",
    "indexed_db/indexed_db_messages.h",
    "indexed_db/indexed_db_param_traits.cc",
    "indexed_db/indexed_db_param_traits.h",
    "input/event_with_latency_info.cc",
    "input/event_with_latency_info.h",
    "input/gesture_event_stream_validator.cc",
    "input/gesture_event_stream_validator.h",
    "input/input_event.cc",
    "input/input_event.h",
    "input/input_event_ack.cc",
    "input/input_event_ack.h",
    "input/input_event_dispatch_type.h",
    "input/input_event_stream_validator.cc",
    "input/input_event_stream_validator.h",
    "input/input_param_traits.cc",
    "input/input_param_traits.h",
    "input/synthetic_gesture_packet.cc",
    "input/synthetic_gesture_packet.h",
    "input/synthetic_gesture_params.cc",
    "input/synthetic_gesture_params.h",
    "input/synthetic_pinch_gesture_params.cc",
    "input/synthetic_pinch_gesture_params.h",
    "input/synthetic_pointer_action_params.cc",
    "input/synthetic_pointer_action_params.h",
    "input/synthetic_smooth_drag_gesture_params.cc",
    "input/synthetic_smooth_drag_gesture_params.h",
    "input/synthetic_smooth_scroll_gesture_params.cc",
    "input/synthetic_smooth_scroll_gesture_params.h",
    "input/synthetic_tap_gesture_params.cc",
    "input/synthetic_tap_gesture_params.h",
    "input/synthetic_web_input_event_builders.cc",
    "input/synthetic_web_input_event_builders.h",
    "input/touch_event_stream_validator.cc",
    "input/touch_event_stream_validator.h",
    "input/web_input_event_queue.h",
    "input/web_touch_event_traits.cc",
    "input/web_touch_event_traits.h",
    "input_messages.h",
    "inter_process_time_ticks_converter.cc",
    "inter_process_time_ticks_converter.h",
    "layer_tree_settings_factory.cc",
    "layer_tree_settings_factory.h",
    "mac/attributed_string_coder.h",
    "mac/attributed_string_coder.mm",
    "mac/font_descriptor.h",
    "mac/font_descriptor.mm",
    "mac/font_loader.h",
    "mac/font_loader.mm",
    "manifest_manager_messages.h",
    "media/aec_dump_messages.h",
    "media/audio_messages.h",
    "media/cdm_info.cc",
    "media/cdm_messages.h",
    "media/cdm_messages_enums.h",
    "media/media_metadata_sanitizer.cc",
    "media/media_metadata_sanitizer.h",
    "media/media_player_delegate_messages.h",
    "media/media_player_messages_android.h",
    "media/media_session_messages_android.h",
    "media/media_stream_messages.h",
    "media/media_stream_options.cc",
    "media/media_stream_options.h",
    "media/media_stream_track_metrics_host_messages.h",
    "media/midi_messages.h",
    "media/surface_view_manager_messages_android.h",
    "media/video_capture.h",
    "media/video_capture_messages.h",
    "memory_messages.h",
    "message_port_messages.h",
    "mojo/constants.cc",
    "mojo/constants.h",
    "mojo/embedded_application_runner.cc",
    "mojo/embedded_application_runner.h",
    "mojo/mojo_shell_connection_impl.cc",
    "mojo/mojo_shell_connection_impl.h",
    "navigation_gesture.h",
    "navigation_params.cc",
    "navigation_params.h",
    "net/url_fetcher.cc",
    "net/url_request_service_worker_data.cc",
    "net/url_request_service_worker_data.h",
    "net/url_request_user_data.cc",
    "net/url_request_user_data.h",
    "one_writer_seqlock.cc",
    "one_writer_seqlock.h",
    "origin_trials/trial_token.cc",
    "origin_trials/trial_token.h",
    "origin_trials/trial_token_validator.cc",
    "origin_trials/trial_token_validator.h",
    "origin_util.cc",
    "p2p_messages.h",
    "page_state_serialization.cc",
    "page_state_serialization.h",
    "page_zoom.cc",
    "pepper_file_util.cc",
    "pepper_file_util.h",
    "pepper_plugin_list.cc",
    "pepper_plugin_list.h",
    "pepper_renderer_instance_data.cc",
    "pepper_renderer_instance_data.h",
    "platform_notification_messages.h",
    "plugin_list.cc",
    "plugin_list.h",
    "power_monitor_messages.h",
    "process_type.cc",
    "push_messaging_messages.h",
    "quota_messages.h",
    "render_process_messages.h",
    "resize_params.cc",
    "resize_params.h",
    "resource_messages.cc",
    "resource_messages.h",
    "resource_request.cc",
    "resource_request.h",
    "resource_request_body_impl.cc",
    "resource_request_body_impl.h",
    "resource_request_completion_status.cc",
    "resource_request_completion_status.h",
    "sandbox_init_mac.cc",
    "sandbox_init_mac.h",
    "sandbox_init_win.cc",
    "sandbox_linux/android/sandbox_bpf_base_policy_android.cc",
    "sandbox_linux/android/sandbox_bpf_base_policy_android.h",
    "sandbox_linux/bpf_cros_arm_gpu_policy_linux.cc",
    "sandbox_linux/bpf_cros_arm_gpu_policy_linux.h",
    "sandbox_linux/bpf_gpu_policy_linux.cc",
    "sandbox_linux/bpf_gpu_policy_linux.h",
    "sandbox_linux/bpf_ppapi_policy_linux.cc",
    "sandbox_linux/bpf_ppapi_policy_linux.h",
    "sandbox_linux/bpf_renderer_policy_linux.cc",
    "sandbox_linux/bpf_renderer_policy_linux.h",
    "sandbox_linux/bpf_utility_policy_linux.cc",
    "sandbox_linux/bpf_utility_policy_linux.h",
    "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
    "sandbox_linux/sandbox_bpf_base_policy_linux.h",
    "sandbox_linux/sandbox_debug_handling_linux.cc",
    "sandbox_linux/sandbox_debug_handling_linux.h",
    "sandbox_linux/sandbox_init_linux.cc",
    "sandbox_linux/sandbox_linux.cc",
    "sandbox_linux/sandbox_linux.h",
    "sandbox_linux/sandbox_seccomp_bpf_linux.cc",
    "sandbox_linux/sandbox_seccomp_bpf_linux.h",
    "sandbox_mac.h",
    "sandbox_mac.mm",
    "sandbox_win.cc",
    "sandbox_win.h",
    "savable_subframe.h",
    "savable_url_schemes.cc",
    "savable_url_schemes.h",
    "screen_orientation_messages.h",
    "security_style_util.cc",
    "security_style_util.h",
    "send_zygote_child_ping_linux.cc",
    "service_worker/embedded_worker_messages.h",
    "service_worker/embedded_worker_settings.h",
    "service_worker/service_worker_client_info.cc",
    "service_worker/service_worker_client_info.h",
    "service_worker/service_worker_messages.h",
    "service_worker/service_worker_status_code.cc",
    "service_worker/service_worker_status_code.h",
    "service_worker/service_worker_type_converters.cc",
    "service_worker/service_worker_type_converters.h",
    "service_worker/service_worker_types.cc",
    "service_worker/service_worker_types.h",
    "service_worker/service_worker_utils.cc",
    "service_worker/service_worker_utils.h",
    "set_process_title.cc",
    "set_process_title.h",
    "set_process_title_linux.cc",
    "set_process_title_linux.h",
    "site_isolation_policy.cc",
    "site_isolation_policy.h",
    "speech_recognition_messages.h",
    "swapped_out_messages.cc",
    "swapped_out_messages.h",
    "text_input_client_messages.h",
    "text_input_state.cc",
    "text_input_state.h",
    "url_schemes.cc",
    "url_schemes.h",
    "user_agent.cc",
    "utility_messages.h",
    "view_message_enums.h",
    "view_messages.h",
    "worker_messages.h",
    "zygote_commands_linux.h",
  ]

  configs += [
    "//content:content_implementation",
    "//build/config:precompiled_headers",
    "//build/config/compiler:no_size_t_to_int_warning",
    "//media/gpu:gpu_config",
  ]

  public_deps = [
    ":mojo_bindings",
    "//cc",
    "//gpu/command_buffer/common",
    "//ipc",
    "//third_party/WebKit/public:blink_headers",
  ]
  deps = [
    # This looks needless as we have :mojo_bindings in public_deps, but it's
    # needed because of allow_circular_includes_from.
    ":mojo_bindings_cpp_sources",
    "//base",
    "//base/third_party/dynamic_annotations",
    "//build/util:webkit_version",
    "//cc/ipc",
    "//cc/surfaces",
    "//components/tracing",
    "//components/tracing:startup_tracing",
    "//content:resources",
    "//content/app/resources",
    "//device/bluetooth",
    "//gpu",
    "//gpu/command_buffer/client:gles2_c_lib",
    "//gpu/command_buffer/client:gles2_cmd_helper",
    "//gpu/command_buffer/client:gles2_implementation",
    "//gpu/command_buffer/client:gles2_interface",
    "//gpu/command_buffer/common:gles2_utils",
    "//gpu/command_buffer/service",
    "//gpu/ipc/client",
    "//gpu/ipc/common",
    "//gpu/skia_bindings",
    "//ipc",
    "//ipc:mojom",
    "//media",
    "//media:shared_memory_support",
    "//media/base/ipc",
    "//media/capture",
    "//media/gpu/ipc/client",
    "//media/gpu/ipc/common",
    "//media/midi",
    "//mojo/common:common_base",
    "//mojo/edk/system",
    "//net",
    "//sandbox",
    "//services/shell",
    "//services/shell/public/cpp",
    "//services/shell/public/interfaces",
    "//services/shell/runner/common",
    "//services/ui/public/interfaces",
    "//skia",
    "//storage/common",
    "//third_party/WebKit/public:blink_minimal",
    "//third_party/boringssl",
    "//third_party/icu",
    "//third_party/libjingle",
    "//third_party/webrtc/base:rtc_base",
    "//ui/accessibility",
    "//ui/base",
    "//ui/base/ime",
    "//ui/display",
    "//ui/events/blink",
    "//ui/events/ipc",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//ui/gfx/ipc",
    "//ui/gfx/ipc/color",
    "//ui/gfx/ipc/geometry",
    "//ui/gfx/ipc/skia",
    "//ui/gl",
    "//ui/shell_dialogs",
    "//url",
    "//url/ipc:url_ipc",
  ]

  defines = []
  include_dirs = []
  libs = []
  ldflags = []

  allow_circular_includes_from = [ ":mojo_bindings_cpp_sources" ]

  if (is_android && use_seccomp_bpf) {
    set_sources_assignment_filter([])
    sources += [
      "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
      "sandbox_linux/sandbox_bpf_base_policy_linux.h",
    ]
    set_sources_assignment_filter(sources_assignment_filter)
  }

  if (is_mac) {
    deps += [ "//sandbox/mac:seatbelt" ]
  }

  if (is_android) {
    deps += [
      "//content/public/android:common_aidl",
      "//content/public/android:jni",
    ]

    libs += [ "android" ]
  }

  if (is_debug && !is_component_build && enable_plugins) {
    # Content depends on the PPAPI message logging stuff; if this isn't here,
    # some unit test binaries won't compile. This only worked in release mode
    # because logging is disabled there.
    deps += [ "//ppapi/proxy:ipc_sources" ]
  }

  if (use_ozone) {
    deps += [ "//ui/ozone" ]
  } else {
    sources -= [ "cursors/webcursor_ozone.cc" ]
  }

  if (!use_aura || is_android) {
    sources -= [ "cursors/webcursor_aura.cc" ]
  }

  if (!use_aura || !use_x11) {
    sources -= [ "cursors/webcursor_aurax11.cc" ]
  }

  if (is_linux) {
    deps += [ "//build/linux:fontconfig" ]
  }

  if (is_mac || is_win || is_android) {
    sources -= [ "font_list_fontconfig.cc" ]
  }

  if (enable_plugins) {
    deps += [
      "//ppapi/proxy",
      "//ppapi/shared_impl",
    ]
  } else {
    sources -= [
      "pepper_file_util.cc",
      "pepper_file_util.h",
      "pepper_plugin_list.cc",
      "pepper_plugin_list.h",
      "pepper_renderer_instance_data.cc",
      "pepper_renderer_instance_data.h",
      "plugin_list.cc",
      "plugin_list.h",
    ]
  }

  if (!is_win || !use_aura) {
    sources -= [ "cursors/webcursor_aurawin.cc" ]
  }

  if (use_seccomp_bpf) {
    defines += [ "USE_SECCOMP_BPF" ]
  } else {
    if (is_linux) {
      sources -= [
        "sandbox_linux/bpf_cros_arm_gpu_policy_linux.cc",
        "sandbox_linux/bpf_cros_arm_gpu_policy_linux.h",
        "sandbox_linux/bpf_gpu_policy_linux.cc",
        "sandbox_linux/bpf_gpu_policy_linux.h",
        "sandbox_linux/bpf_ppapi_policy_linux.cc",
        "sandbox_linux/bpf_ppapi_policy_linux.h",
        "sandbox_linux/bpf_renderer_policy_linux.cc",
        "sandbox_linux/bpf_renderer_policy_linux.h",
        "sandbox_linux/bpf_utility_policy_linux.cc",
        "sandbox_linux/bpf_utility_policy_linux.h",
        "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
        "sandbox_linux/sandbox_bpf_base_policy_linux.h",
      ]
    }
    if (is_android) {
      sources -= [
        "sandbox_linux/android/sandbox_bpf_base_policy_android.cc",
        "sandbox_linux/android/sandbox_bpf_base_policy_android.h",
      ]
    }
  }

  if (is_mac) {
    deps += [ "//media/gpu" ]
  }

  if (enable_ipc_fuzzer) {
    configs += [ "//tools/ipc_fuzzer:ipc_fuzzer_config" ]
    sources += [
      "external_ipc_dumper.cc",
      "external_ipc_dumper.h",
    ]
  }
}

# See comment at the top of //content/BUILD.gn for how this works.
group("for_content_tests") {
  visibility = [ "//content/test/*" ]
  if (!is_component_build) {
    public_deps = [
      ":common",
    ]
  }
}

mojom("mojo_bindings") {
  # This interface is internal to content.
  visibility = [ "//content/*" ]

  sources = [
    "frame.mojom",
    "image_downloader/image_downloader.mojom",
    "leveldb_wrapper.mojom",
    "render_frame_message_filter.mojom",
    "render_widget_window_tree_client_factory.mojom",
    "service_worker/embedded_worker_setup.mojom",
    "storage_partition_service.mojom",
    "url_loader.mojom",
    "url_loader_factory.mojom",
  ]

  import_dirs = [ "//mojo/services" ]

  public_deps = [
    "//components/leveldb/public/interfaces",
    "//device/sensors/public/interfaces",
    "//services/shell/public/interfaces",
    "//services/ui/public/interfaces",
    "//skia/public/interfaces",
    "//third_party/WebKit/public:mojo_bindings",
    "//ui/gfx/geometry/mojo",
    "//url/mojo:url_mojom_gurl",
    "//url/mojo:url_mojom_origin",
  ]

  export_class_attribute = "CONTENT_EXPORT"
  export_define = "CONTENT_IMPLEMENTATION=1"
  export_header = "content/common/content_export.h"
}