tools/ApplyTag/build.scons

#!/usr/bin/python2.4
#
# Copyright 2009 Google Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
# ========================================================================


Import('env')


local_env = env.Clone()
local_env.Append(
    LIBS = [
        ('atls.lib', 'atlsd.lib')[local_env.Bit('debug')],
        ('libcmt.lib', 'libcmtd.lib')[local_env.Bit('debug')],
        ('libcpmt.lib', 'libcpmtd.lib')[local_env.Bit('debug')],
        'netapi32.lib',
        'psapi.lib',
        'rasapi32.lib',
        'shlwapi.lib',
        'userenv.lib',
        'version.lib',
        'wtsapi32.lib',
        '$LIB_DIR/common.lib',
        ],
    CPPDEFINES = [
        'UNICODE',
        '_UNICODE'
        ],
)

# ApplyTag.exe is a console application
local_env.FilterOut(LINKFLAGS = ['/SUBSYSTEM:WINDOWS'])
local_env['LINKFLAGS'] += ['/SUBSYSTEM:CONSOLE']

local_env.Dir('.').addRepository(local_env.Dir('$MAIN_DIR/common'))

target_name = 'ApplyTag.exe'

inputs = [
    'apply_tag.cc',  # Comes from $MAIN_DIR/common
    'apply_tag_tool.cc',
    ]
if env.Bit('use_precompiled_headers'):
  inputs += local_env.EnablePrecompile(target_name)

local_env.ComponentProgram(
    prog_name=target_name,
    source=inputs,
)