infra/config/subprojects/buildinfra.star

# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

"""Definitions of https://chromium.googlesource.com/build.git CI resources."""

load("//lib/build.star", "build")
load("//lib/infra.star", "infra")

REPO_URL = "https://chromium.googlesource.com/build"

infra.console_view(
    # build is already taken by chromium/tools/build.git.
    # This disambiguation will result in the console URL:
    # https://ci.chromium.org/p/infra/g/buildinfra/console
    name = "buildinfra",
    title = "build repository console",
    repo = REPO_URL,
)
infra.cq_group(
    name = "buildinfra",
    repo = REPO_URL,
)

def ci_builder(name, os):
    infra.builder(
        name = name,
        bucket = "ci",
        executable = infra.recipe(
            "buildinfra",
        ),
        os = os,
        triggered_by = [
            luci.gitiles_poller(
                name = "buildinfra-gitiles-trigger",
                bucket = "ci",
                repo = REPO_URL,
                refs = ["refs/heads/main"],
            ),
        ],
    )
    luci.console_view_entry(
        builder = name,
        console_view = "buildinfra",
        category = infra.category_from_os(os),
    )

def try_builder(name, os):
    infra.builder(
        name = name,
        bucket = "try",
        executable = infra.recipe(
            "buildinfra",
        ),
        os = os,
    )
    luci.cq_tryjob_verifier(
        builder = name,
        cq_group = "buildinfra",
    )

ci_builder(name = "buildinfra-continuous-linux", os = "Ubuntu-22.04")
ci_builder(name = "buildinfra-continuous-mac", os = "Mac-12")
ci_builder(name = "buildinfra-continuous-win", os = "Windows-10")

try_builder(name = "buildinfra-try-linux", os = "Ubuntu-22.04")
try_builder(name = "buildinfra-try-mac", os = "Mac-12")
try_builder(name = "buildinfra-try-win", os = "Windows-10")

# Presubmit trybot.
build.presubmit(
    name = "buildinfra-try-presubmit",
    cq_group = "buildinfra",
    os = "Ubuntu-22.04",
)