infra/config/subprojects/wpt.star

# Copyright 2019 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

"""Definitions of WPT import/export/upload crons."""

load("//lib/build.star", "build")

def cron(name, recipe, description_html = None, execution_timeout = None, schedule = None):
    luci.builder(
        name = name,
        contact_team_email = "chrome-blink-engprod@google.com",
        description_html = description_html,
        bucket = "cron",
        executable = build.recipe(recipe),
        dimensions = {
            "builderless": "1",
            "os": "Ubuntu-22.04",
            "cpu": "x86-64",
            "pool": "luci.infra.cron",
        },
        service_account = "wpt-autoroller@chops-service-accounts.iam.gserviceaccount.com",
        execution_timeout = execution_timeout or time.hour,
        schedule = schedule or "with 60s interval",
    )
    luci.list_view_entry(
        builder = name,
        list_view = "cron",
    )

cron(
    name = "wpt-exporter",
    recipe = "wpt_export",
    description_html = '<a href="{}">Exports web platform test changes</a> from Chromium to GitHub.'.format(
        "https://chromium.googlesource.com/chromium/src/+/HEAD/docs/testing/web_platform_tests.md#Exporting-tests",
    ),
)
cron(
    name = "wpt-importer",
    recipe = "wpt_import",
    description_html = '<a href="{}">Imports web platform test changes</a> from GitHub to Chromium.'.format(
        "https://chromium.googlesource.com/chromium/src/+/HEAD/docs/testing/web_platform_tests.md#Importing-tests",
    ),
    schedule = "with 1800s interval",
    execution_timeout = 6 * time.hour,
)
cron(
    name = "wpt-uploader",
    recipe = "wpt_upload",
    description_html = 'Uploads Chromium CI test results to <a href="{}">wpt.fyi</a>.'.format(
        "https://wpt.fyi/status",
    ),
    schedule = "with 10800s interval",
)