infra/config/subprojects/luci-py.star

# Copyright 2019 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

"""Definitions of luci-py.git CI resources."""

load("//lib/build.star", "build")
load("//lib/infra.star", "infra")

cq_group = "luci-py"

infra.cq_group(
    name = cq_group,
    repo = "https://chromium.googlesource.com/infra/luci/luci-py",
)

def try_builder(
        name,
        os,
        recipe = None,
        disable_reuse = None,
        experiment_percentage = None,
        owner_whitelist = None,
        mode_allowlist = None,
        properties = None,
        in_cq = True):
    infra.builder(
        name = name,
        bucket = "try",
        executable = infra.recipe(recipe or "luci_py"),
        os = os,
        properties = properties,
    )
    if in_cq:
        luci.cq_tryjob_verifier(
            builder = name,
            cq_group = cq_group,
            disable_reuse = disable_reuse,
            experiment_percentage = experiment_percentage,
            owner_whitelist = owner_whitelist,
            mode_allowlist = mode_allowlist,
        )

build.presubmit(
    name = "luci-py-try-presubmit",
    cq_group = cq_group,
    repo_name = "luci_py",
    os = "Ubuntu-24.04",
    # The default 8-minute timeout is a problem for luci-py.
    # See https://crbug.com/917479 for context.
    timeout_s = 900,
)

try_builder(
    name = "luci-py-try-linux",
    os = "Ubuntu-24.04",
)

try_builder(
    name = "luci-py-try-mac",
    os = "Mac-12",
)

try_builder(
    name = "luci-py-try-win10-64",
    os = "Windows-10",
)