| @echo off |
| |
| cd %~dp0 |
| |
| if /i "%1"=="help" goto help |
| if /i "%1"=="--help" goto help |
| if /i "%1"=="-help" goto help |
| if /i "%1"=="/help" goto help |
| if /i "%1"=="?" goto help |
| if /i "%1"=="-?" goto help |
| if /i "%1"=="--?" goto help |
| if /i "%1"=="/?" goto help |
| |
| @rem Process arguments. |
| set config=Release |
| set target=Build |
| set target_arch=x86 |
| set debug_arg= |
| set snapshot_arg= |
| set noprojgen= |
| set nobuild= |
| set nosign= |
| set nosnapshot= |
| set test_args= |
| set msi= |
| set upload= |
| set licensertf= |
| set jslint= |
| set buildnodeweak= |
| set noetw= |
| set noetw_arg= |
| set noetw_msi_arg= |
| set noperfctr= |
| set noperfctr_arg= |
| set noperfctr_msi_arg= |
| set i18n_arg= |
| set download_arg= |
| |
| :next-arg |
| if "%1"=="" goto args-done |
| if /i "%1"=="debug" set config=Debug&goto arg-ok |
| if /i "%1"=="release" set config=Release&goto arg-ok |
| if /i "%1"=="clean" set target=Clean&goto arg-ok |
| if /i "%1"=="ia32" set target_arch=x86&goto arg-ok |
| if /i "%1"=="x86" set target_arch=x86&goto arg-ok |
| if /i "%1"=="x64" set target_arch=x64&goto arg-ok |
| if /i "%1"=="noprojgen" set noprojgen=1&goto arg-ok |
| if /i "%1"=="nobuild" set nobuild=1&goto arg-ok |
| if /i "%1"=="nosign" set nosign=1&goto arg-ok |
| if /i "%1"=="nosnapshot" set nosnapshot=1&goto arg-ok |
| if /i "%1"=="noetw" set noetw=1&goto arg-ok |
| if /i "%1"=="noperfctr" set noperfctr=1&goto arg-ok |
| if /i "%1"=="licensertf" set licensertf=1&goto arg-ok |
| if /i "%1"=="test" set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok |
| if /i "%1"=="test-ci" set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok |
| if /i "%1"=="test-simple" set test_args=%test_args% sequential parallel -J&goto arg-ok |
| if /i "%1"=="test-message" set test_args=%test_args% message&goto arg-ok |
| if /i "%1"=="test-gc" set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok |
| if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok |
| if /i "%1"=="test-pummel" set test_args=%test_args% pummel&goto arg-ok |
| if /i "%1"=="test-all" set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok |
| if /i "%1"=="jslint" set jslint=1&goto arg-ok |
| if /i "%1"=="msi" set msi=1&set licensertf=1&goto arg-ok |
| if /i "%1"=="upload" set upload=1&goto arg-ok |
| if /i "%1"=="small-icu" set i18n_arg=%1&goto arg-ok |
| if /i "%1"=="full-icu" set i18n_arg=%1&goto arg-ok |
| if /i "%1"=="intl-none" set i18n_arg=%1&goto arg-ok |
| if /i "%1"=="download-all" set download_arg="--download=all"&goto arg-ok |
| |
| echo Warning: ignoring invalid command line option `%1`. |
| |
| :arg-ok |
| :arg-ok |
| shift |
| goto next-arg |
| |
| :args-done |
| if "%config%"=="Debug" set debug_arg=--debug |
| if defined nosnapshot set snapshot_arg=--without-snapshot |
| if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1 |
| if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1 |
| |
| if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu |
| if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu |
| if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none |
| |
| call :getnodeversion || exit /b 1 |
| |
| @rem Set environment for msbuild |
| |
| @rem Look for Visual Studio 2015 |
| if not defined VS140COMNTOOLS goto vc-set-2013 |
| if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013 |
| if "%VCVARS_VER%" NEQ "140" ( |
| call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" |
| SET VCVARS_VER=140 |
| ) |
| if not defined VCINSTALLDIR goto vc-set-2013 |
| set GYP_MSVS_VERSION=2015 |
| goto msbuild-found |
| |
| :vc-set-2013 |
| @rem Look for Visual Studio 2013 |
| if not defined VS120COMNTOOLS goto msbuild-not-found |
| if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found |
| if "%VCVARS_VER%" NEQ "120" ( |
| call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" |
| SET VCVARS_VER=120 |
| ) |
| if not defined VCINSTALLDIR goto msbuild-not-found |
| set GYP_MSVS_VERSION=2013 |
| goto msbuild-found |
| |
| :msbuild-not-found |
| echo Failed to find Visual Studio installation. |
| goto exit |
| |
| :msbuild-found |
| |
| :project-gen |
| @rem Skip project generation if requested. |
| if defined noprojgen goto msbuild |
| |
| @rem Generate the VS project. |
| python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG% |
| if errorlevel 1 goto create-msvs-files-failed |
| if not exist node.sln goto create-msvs-files-failed |
| echo Project files generated. |
| |
| :msbuild |
| @rem Skip build if requested. |
| if defined nobuild goto sign |
| |
| @rem Build the sln with msbuild. |
| msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo |
| if errorlevel 1 goto exit |
| if "%target%" == "Clean" goto exit |
| |
| :sign |
| @rem Skip signing if the `nosign` option was specified. |
| if defined nosign goto licensertf |
| |
| signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe |
| if errorlevel 1 echo Failed to sign exe&goto exit |
| |
| :licensertf |
| @rem Skip license.rtf generation if not requested. |
| if not defined licensertf goto msi |
| |
| %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf |
| if errorlevel 1 echo Failed to generate license.rtf&goto exit |
| |
| :msi |
| @rem Skip msi generation if not requested |
| if not defined msi goto run |
| |
| :msibuild |
| echo Building iojs-v%FULLVERSION%-%target_arch%.msi |
| msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo |
| if errorlevel 1 goto exit |
| |
| if defined nosign goto upload |
| signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll iojs-v%FULLVERSION%-%target_arch%.msi |
| if errorlevel 1 echo Failed to sign msi&goto exit |
| |
| :upload |
| @rem Skip upload if not requested |
| if not defined upload goto run |
| |
| if not defined SSHCONFIG ( |
| echo SSHCONFIG is not set for upload |
| exit /b 1 |
| ) |
| if not defined STAGINGSERVER set STAGINGSERVER=iojs-www |
| ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%" |
| scp -F %SSHCONFIG% Release\iojs.exe %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.exe |
| scp -F %SSHCONFIG% Release\iojs.lib %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.lib |
| scp -F %SSHCONFIG% iojs-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/ |
| ssh -F %SSHCONFIG% %STAGINGSERVER% "touch staging/%DISTTYPEDIR%/v%FULLVERSION%/iojs-v%FULLVERSION%-%target_arch%.msi.done staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done" |
| |
| :run |
| @rem Run tests if requested. |
| |
| :build-node-weak |
| @rem Build node-weak if required |
| if "%buildnodeweak%"=="" goto run-tests |
| "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0." |
| if errorlevel 1 goto build-node-weak-failed |
| goto run-tests |
| |
| :build-node-weak-failed |
| echo Failed to build node-weak. |
| goto exit |
| |
| :run-tests |
| if "%test_args%"=="" goto jslint |
| if "%config%"=="Debug" set test_args=--mode=debug %test_args% |
| if "%config%"=="Release" set test_args=--mode=release %test_args% |
| echo running 'cctest' |
| "%config%\cctest" |
| echo running 'python tools\test.py %test_args%' |
| python tools\test.py %test_args% |
| goto jslint |
| |
| :jslint |
| if not defined jslint goto exit |
| echo running jslint |
| %config%\iojs tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet |
| goto exit |
| |
| :create-msvs-files-failed |
| echo Failed to create vc project files. |
| goto exit |
| |
| :help |
| echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all] |
| echo Examples: |
| echo vcbuild.bat : builds release build |
| echo vcbuild.bat debug : builds debug build |
| echo vcbuild.bat release msi : builds release build and MSI installer package |
| echo vcbuild.bat test : builds debug build and runs tests |
| goto exit |
| |
| :exit |
| goto :EOF |
| |
| rem *************** |
| rem Subroutines |
| rem *************** |
| |
| :getnodeversion |
| set NODE_VERSION= |
| set TAG= |
| set FULLVERSION= |
| |
| for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i |
| if not defined NODE_VERSION ( |
| echo Cannot determine current version of io.js |
| exit /b 1 |
| ) |
| |
| if not defined DISTTYPE set DISTTYPE=release |
| if "%DISTTYPE%"=="release" ( |
| set FULLVERSION=%NODE_VERSION% |
| goto exit |
| ) |
| if "%DISTTYPE%"=="custom" ( |
| if not defined CUSTOMTAG ( |
| echo "CUSTOMTAG is not set for DISTTYPE=custom" |
| exit /b 1 |
| ) |
| set TAG=%CUSTOMTAG% |
| ) |
| if not "%DISTTYPE%"=="custom" ( |
| if not defined DATESTRING ( |
| echo "DATESTRING is not set for nightly" |
| exit /b 1 |
| ) |
| if not defined COMMIT ( |
| echo "COMMIT is not set for nightly" |
| exit /b 1 |
| ) |
| if not "%DISTTYPE%"=="nightly" ( |
| if not "%DISTTYPE%"=="next-nightly" ( |
| echo "DISTTYPE is not release, custom, nightly or next-nightly" |
| exit /b 1 |
| ) |
| ) |
| set TAG=%DISTTYPE%%DATESTRING%%COMMIT% |
| ) |
| set FULLVERSION=%NODE_VERSION%-%TAG% |
| |
| :exit |
| if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE% |
| goto :EOF |
