| # Copyright 1999-2014 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Header: /var/cvsroot/gentoo-x86/dev-python/ply/ply-3.4-r1.ebuild,v 1.10 2014/04/02 20:53:56 radhermit Exp $ |
| |
| EAPI=5 |
| |
| PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} pypy pypy2_0 ) |
| |
| inherit distutils-r1 |
| |
| DESCRIPTION="Python Lex-Yacc library" |
| HOMEPAGE="http://www.dabeaz.com/ply/ http://pypi.python.org/pypi/ply" |
| SRC_URI="http://www.dabeaz.com/ply/${P}.tar.gz" |
| |
| LICENSE="BSD" |
| SLOT="0" |
| KEYWORDS="*" |
| IUSE="examples" |
| |
| DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]" |
| RDEPEND="" |
| |
| DOCS=( ANNOUNCE CHANGES README TODO ) |
| |
| python_test() { |
| cp -r -l test "${BUILD_DIR}"/ || die |
| cd "${BUILD_DIR}"/test || die |
| |
| local t |
| for t in testlex.py testyacc.py; do |
| "${PYTHON}" "${t}" || die "${t} fails with ${EPYTHON}" |
| done |
| } |
| |
| python_install_all() { |
| local HTML_DOCS=( doc/. ) |
| use examples && local EXAMPLES=( example/. ) |
| distutils-r1_python_install_all |
| } |