| # Copyright 1999-2016 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=6 |
| |
| PYTHON_COMPAT=( python2_7 python3_{4,5} ) |
| |
| inherit distutils-r1 |
| |
| DESCRIPTION="Converting Jupyter Notebooks" |
| HOMEPAGE="http://jupyter.org" |
| SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz" |
| |
| LICENSE="BSD" |
| SLOT="0" |
| KEYWORDS="~amd64 ~x86" |
| IUSE="doc test" |
| |
| RDEPEND=" |
| dev-python/jupyter_core[${PYTHON_USEDEP}] |
| dev-python/nbformat[${PYTHON_USEDEP}] |
| dev-python/mistune[${PYTHON_USEDEP}] |
| dev-python/jinja[${PYTHON_USEDEP}] |
| dev-python/pygments[${PYTHON_USEDEP}] |
| dev-python/traitlets[${PYTHON_USEDEP}] |
| dev-python/entrypoints[${PYTHON_USEDEP}] |
| " |
| DEPEND="${RDEPEND} |
| doc? ( |
| dev-python/ipython[${PYTHON_USEDEP}] |
| dev-python/jupyter_client[${PYTHON_USEDEP}] |
| dev-python/sphinx[${PYTHON_USEDEP}] |
| dev-python/nbsphinx[${PYTHON_USEDEP}] |
| app-text/pandoc |
| ) |
| test? ( |
| dev-python/nose[${PYTHON_USEDEP}] |
| dev-python/coverage[${PYTHON_USEDEP}] |
| dev-python/ipykernel[${PYTHON_USEDEP}] |
| ) |
| " |
| |
| python_prepare_all() { |
| # Prevent un-needed download during build |
| if use doc; then |
| sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die |
| fi |
| |
| distutils-r1_python_prepare_all |
| } |
| |
| python_compile_all() { |
| use doc && emake -C docs html |
| } |
| |
| python_test() { |
| distutils_install_for_testing |
| cd "${TEST_DIR}"/lib || die |
| nosetests --with-coverage --cover-package=nbconvert nbconvert || die |
| } |
| |
| python_install_all() { |
| use doc && HTML_DOCS=( docs/build/html/. ) |
| distutils-r1_python_install_all |
| } |
| |
| pkg_postinst() { |
| if ! has_version app-text/pandoc ; then |
| einfo "Pandoc is required for converting to formats other than Python," |
| einfo "HTML, and Markdown. If you need this functionality, install" |
| einfo "app-text/pandoc." |
| fi |
| } |