sys-apps/portage/portage-2.1.7.16.ebuild - chromiumos/overlays/portage - Git at Google

 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/portage-2.1.7.16.ebuild,v 1.9 2010/02/23 10:41:05 zmedico Exp $

 # Require EAPI 2 since we now require at least python-2.6 (for python 3
 # syntax support) which also requires EAPI 2.
 EAPI=2
 inherit eutils multilib python

 DESCRIPTION="Portage is the package management and distribution system for Gentoo"
 HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
 LICENSE="GPL-2"
 KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd"
 PROVIDE="virtual/portage"
 SLOT="0"
 IUSE="build doc epydoc linguas_pl python3 selinux"

 python_dep="python3? ( =dev-lang/python-3* )
 	!python3? ( || ( dev-lang/python:2.8 dev-lang/python:2.7 dev-lang/python:2.6 >=dev-lang/python-3 ) )"

 # The pysqlite blocker is for bug #282760.
 DEPEND="${python_dep}
 	!build? ( >=sys-apps/sed-4.0.5 )
 	doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
 	epydoc? ( >=dev-python/epydoc-2.0 !<=dev-python/pysqlite-2.4.1 )"
 RDEPEND="${python_dep}
 	!build? ( >=sys-apps/sed-4.0.5
 		>=app-shells/bash-3.2_p17
 		>=app-admin/eselect-1.2 )
 	elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
 	elibc_glibc? ( >=sys-apps/sandbox-1.6 )
 	elibc_uclibc? ( >=sys-apps/sandbox-1.6 )
 	>=app-misc/pax-utils-0.1.17
 	selinux? ( sys-libs/libselinux )"
 PDEPEND="
 	!build? (
 		>=net-misc/rsync-2.6.4
 		userland_GNU? ( >=sys-apps/coreutils-6.4 )
 	)"
 # coreutils-6.4 rdep is for date format in emerge-webrsync #164532
 # rsync-2.6.4 rdep is for the --filter option #167668

 SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"

 prefix_src_archives() {
 	local x y
 	for x in ${@}; do
 		for y in ${SRC_ARCHIVES}; do
 			echo ${y}/${x}
 		done
 	done
 }

 PV_PL="2.1.2"
 PATCHVER_PL=""
 TARBALL_PV=2.1.7
 SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
 	$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)
 	linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
 		$(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"

 PATCHVER=$PV
 if [ -n "${PATCHVER}" ]; then
 	SRC_URI="${SRC_URI} mirror://gentoo/${PN}-${PATCHVER}.patch.bz2
 	$(prefix_src_archives ${PN}-${PATCHVER}.patch.bz2)"
 fi

 S="${WORKDIR}"/${PN}-${TARBALL_PV}
 S_PL="${WORKDIR}"/${PN}-${PV_PL}

 compatible_python_is_selected() {
 	[[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x2060000 and "good" or "bad")') = good ]]
 }

 pkg_setup() {
 	if ! use python3 && ! compatible_python_is_selected ; then
 		ewarn "Attempting to select a compatible default python interpreter"
 		local x success=0
 		for x in /usr/bin/python2.* ; do
 			x=${x#/usr/bin/python2.}
 			if [[ $x -ge 6 ]] 2>/dev/null ; then
 				eselect python set python2.$x
 				if compatible_python_is_selected ; then
 					elog "Default python interpreter is now set to python-2.$x"
 					success=1
 					break
 				fi
 			fi
 		done
 		if [ $success != 1 ] ; then
 			eerror "Unable to select a compatible default python interpreter!"
 			die "This version of portage requires at least python-2.6 to be selected as the default python interpreter (see \`eselect python --help\`)."
 		fi
 	fi
 }

 src_prepare() {
 	if [ -n "${PATCHVER}" ] ; then
 		if [[ -L $S/bin/ebuild-helpers/portageq ]] ; then
 			rm "$S/bin/ebuild-helpers/portageq" \
 				|| die "failed to remove portageq helper symlink"
 		fi
 		epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
 	fi
 	einfo "Setting portage.VERSION to ${PVR} ..."
 	sed -i "s/^VERSION=.*/VERSION=\"${PVR}\"/" pym/portage/__init__.py || \
 		die "Failed to patch portage.VERSION"

 	if use python3; then
 		python_convert_shebangs -r 3 .
 	fi
 }

 src_compile() {
 	if use doc; then
 		cd "${S}"/doc
 		touch fragment/date
 		make xhtml xhtml-nochunks || die "failed to make docs"
 	fi

 	if use epydoc; then
 		einfo "Generating api docs"
 		mkdir "${WORKDIR}"/api
 		local my_modules epydoc_opts=""
 		# A name collision between the portage.dbapi class and the
 		# module with the same name triggers an epydoc crash unless
 		# portage.dbapi is excluded from introspection.
 		ROOT=/ has_version '>=dev-python/epydoc-3_pre0' && \
 			epydoc_opts='--exclude-introspect portage\.dbapi'
 		my_modules="$(find "${S}/pym" -name "*.py" \
 			| sed -e 's:/__init__.py$::' -e 's:\.py$::' -e "s:^${S}/pym/::" \
 			 -e 's:/:.:g' | sort)" || die "error listing modules"
 		# workaround for bug 282760
 		> "$S/pym/pysqlite2.py"
 		PYTHONPATH=${S}/pym:${PYTHONPATH:+:}${PYTHONPATH} \
 			epydoc -o "${WORKDIR}"/api \
 			-qqqqq --no-frames --show-imports $epydoc_opts \
 			--name "${PN}" --url "${HOMEPAGE}" \
 			${my_modules} || die "epydoc failed"
 		rm "$S/pym/pysqlite2.py"
 	fi
 }

 src_test() {
 	PYTHONPATH=${S}/pym:${PYTHONPATH:+:}${PYTHONPATH} \
 		./pym/portage/tests/runTests || die "test(s) failed"
 }

 src_install() {
 	local libdir=$(get_libdir)
 	local portage_base="/usr/${libdir}/portage"
 	local portage_share_config=/usr/share/portage/config

 	cd "${S}"/cnf
 	insinto /etc
 	doins etc-update.conf dispatch-conf.conf || die

 	dodir "${portage_share_config}"
 	insinto "${portage_share_config}"
 	doins "${S}/cnf/make.globals" || die
 	if [ -f "make.conf.${ARCH}".diff ]; then
 		patch make.conf "make.conf.${ARCH}".diff || \
 			die "Failed to patch make.conf.example"
 		newins make.conf make.conf.example || die
 	else
 		eerror ""
 		eerror "Portage does not have an arch-specific configuration for this arch."
 		eerror "Please notify the arch maintainer about this issue. Using generic."
 		eerror ""
 		newins make.conf make.conf.example || die
 	fi

 	dosym ..${portage_share_config}/make.globals /etc/make.globals

 	insinto /etc/logrotate.d
 	doins "${S}"/cnf/logrotate.d/elog-save-summary || die

 	# BSD and OSX need a sed wrapper so that find/xargs work properly
 	if use userland_GNU; then
 		rm "${S}"/bin/ebuild-helpers/sed || die "Failed to remove sed wrapper"
 	fi

 	local x symlinks

 	# current tarball contains outdated stuff
 	rm -rf "$S"/bin/ebuild-helpers/3
 	for x in dohard dosed ; do
 		dosym ../../banned-helper ${portage_base}/bin/ebuild-helpers/4/$x
 	done

 	for x in $(find "$S"/bin -type d) ; do
 		x=${x#$S/}
 		exeinto $portage_base/$x || die "exeinto failed"
 		cd "$S"/$x || die "cd failed"
 		doexe $(find . -mindepth 1 -maxdepth 1 -type f ! -type l) || \
 			die "doexe failed"
 		symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
 		if [ -n "$symlinks" ] ; then
 			cp -P $symlinks "$D$portage_base/$x" || die "cp failed"
 		fi
 	done

 	for x in $(find "$S"/pym -type d) ; do
 		x=${x#$S/}
 		insinto $portage_base/$x || die "insinto failed"
 		cd "$S"/$x || die "cd failed"
 		doins *.py || die "doins failed"
 		symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
 		if [ -n "$symlinks" ] ; then
 			cp -P $symlinks "$D$portage_base/$x" || die "cp failed"
 		fi
 	done

 	# Symlinks to directories cause up/downgrade issues and the use of these
 	# modules outside of portage is probably negligible.
 	for x in "${D}${portage_base}/pym/"{cache,elog_modules} ; do
 		[ ! -L "${x}" ] && continue
 		die "symlink to directory will cause upgrade/downgrade issues: '${x}'"
 	done

 	exeinto ${portage_base}/pym/portage/tests
 	doexe  "${S}"/pym/portage/tests/runTests

 	doman "${S}"/man/*.[0-9]
 	if use linguas_pl; then
 		doman -i18n=pl "${S_PL}"/man/pl/*.[0-9]
 		doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9]
 	fi

 	dodoc "${S}"/{ChangeLog,NEWS,RELEASE-NOTES}
 	use doc && dohtml -r "${S}"/doc/*
 	use epydoc && dohtml -r "${WORKDIR}"/api

 	dodir /usr/bin
 	for x in ebuild egencache emerge portageq repoman ; do
 		dosym ../${libdir}/portage/bin/${x} /usr/bin/${x}
 	done

 	dodir /usr/sbin
 	local my_syms="archive-conf
 		dispatch-conf
 		emaint
 		emerge-webrsync
 		env-update
 		etc-update
 		fixpackages
 		quickpkg
 		regenworld"
 	local x
 	for x in ${my_syms}; do
 		dosym ../${libdir}/portage/bin/${x} /usr/sbin/${x}
 	done
 	dosym env-update /usr/sbin/update-env
 	dosym etc-update /usr/sbin/update-etc

 	dodir /etc/portage
 	keepdir /etc/portage
 }

 pkg_preinst() {
 	if ! use build && ! has_version dev-python/pycrypto && \
 		! has_version '>=dev-lang/python-2.6[ssl]' ; then
 		ewarn "If you are an ebuild developer and you plan to commit ebuilds"
 		ewarn "with this system then please install dev-python/pycrypto or"
 		ewarn "enable the ssl USE flag for >=dev-lang/python-2.6 in order"
 		ewarn "to enable RMD160 hash support."
 		ewarn "See bug #198398 for more information."
 	fi
 	if [ -f "${ROOT}/etc/make.globals" ]; then
 		rm "${ROOT}/etc/make.globals"
 	fi

 	[[ -n $PORTDIR_OVERLAY ]] && has_version "<${CATEGORY}/${PN}-2.1.6.12"
 	REPO_LAYOUT_CONF_WARN=$?
 	has_version "<${CATEGORY}/${PN}-2.1.7"
 	UPGRADE_FROM_2_1=$?
 }

 pkg_postinst() {
 	# Compile all source files recursively. Any orphans
 	# will be identified and removed in postrm.
 	python_mod_optimize /usr/$(get_libdir)/portage/pym

 	local warning_shown=0
 	if [ $REPO_LAYOUT_CONF_WARN = 0 ] ; then
 		ewarn
 		echo "If you want overlay eclasses to override eclasses from" \
 			"other repos then see the portage(5) man page" \
 			"for information about the new layout.conf and repos.conf" \
 			"configuration files." \
 			| fmt -w 75 | while read -r ; do ewarn "$REPLY" ; done
 	fi
 	if [[ $UPGRADE_FROM_2_1 = 0 && -n $PORTAGE_BINHOST ]] ; then
 		ewarn
 		echo "If you have an old PORTAGE_BINHOST setting in /etc/make.conf" \
 		"then you will encounter bug #303211. Therefore, please ensure" \
 		"that your PORTAGE_BINHOST setting points to a remote directory" \
 		"containing a \$PKGDIR/Packages file which is created by" \
 		">=portage-2.1.6. If \$PKGDIR/Packages does not exist on" \
 		"the server or it is incomplete, you must run \`emaint" \
 		"--fix binhost\` on the server in order to generate it." \
 		"See \`man make.conf\` for more information about" \
 		"PORTAGE_BINHOST." | \
 		fmt -w 70 | while read -r ; do ewarn "$REPLY" ; done
 		warning_shown=1
 	fi
 	if [ $warning_shown = 1 ] ; then
 		ewarn # for symmetry
 	fi

 	einfo
 	einfo "For help with using portage please consult the Gentoo Handbook"
 	einfo "at http://www.gentoo.org/doc/en/handbook/handbook-x86.xml?part=3"
 	einfo
 }

 pkg_postrm() {
 	python_mod_cleanup /usr/$(get_libdir)/portage/pym
 }
	# Copyright 1999-2010 Gentoo Foundation
	# Distributed under the terms of the GNU General Public License v2
	# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/portage-2.1.7.16.ebuild,v 1.9 2010/02/23 10:41:05 zmedico Exp $

	# Require EAPI 2 since we now require at least python-2.6 (for python 3
	# syntax support) which also requires EAPI 2.
	EAPI=2
	inherit eutils multilib python

	DESCRIPTION="Portage is the package management and distribution system for Gentoo"
	HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
	LICENSE="GPL-2"
	KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd"
	PROVIDE="virtual/portage"
	SLOT="0"
	IUSE="build doc epydoc linguas_pl python3 selinux"

	python_dep="python3? ( =dev-lang/python-3* )
	!python3? ( \|\| ( dev-lang/python:2.8 dev-lang/python:2.7 dev-lang/python:2.6 >=dev-lang/python-3 ) )"

	# The pysqlite blocker is for bug #282760.
	DEPEND="${python_dep}
	!build? ( >=sys-apps/sed-4.0.5 )
	doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
	epydoc? ( >=dev-python/epydoc-2.0 !<=dev-python/pysqlite-2.4.1 )"
	RDEPEND="${python_dep}
	!build? ( >=sys-apps/sed-4.0.5
	>=app-shells/bash-3.2_p17
	>=app-admin/eselect-1.2 )
	elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
	elibc_glibc? ( >=sys-apps/sandbox-1.6 )
	elibc_uclibc? ( >=sys-apps/sandbox-1.6 )
	>=app-misc/pax-utils-0.1.17
	selinux? ( sys-libs/libselinux )"
	PDEPEND="
	!build? (
	>=net-misc/rsync-2.6.4
	userland_GNU? ( >=sys-apps/coreutils-6.4 )
	)"
	# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
	# rsync-2.6.4 rdep is for the --filter option #167668

	SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"

	prefix_src_archives() {
	local x y
	for x in ${@}; do
	for y in ${SRC_ARCHIVES}; do
	echo ${y}/${x}
	done
	done
	}

	PV_PL="2.1.2"
	PATCHVER_PL=""
	TARBALL_PV=2.1.7
	SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
	$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)
	linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
	$(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"

	PATCHVER=$PV
	if [ -n "${PATCHVER}" ]; then
	SRC_URI="${SRC_URI} mirror://gentoo/${PN}-${PATCHVER}.patch.bz2
	$(prefix_src_archives ${PN}-${PATCHVER}.patch.bz2)"
	fi

	S="${WORKDIR}"/${PN}-${TARBALL_PV}
	S_PL="${WORKDIR}"/${PN}-${PV_PL}

	compatible_python_is_selected() {
	[[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x2060000 and "good" or "bad")') = good ]]
	}

	pkg_setup() {
	if ! use python3 && ! compatible_python_is_selected ; then
	ewarn "Attempting to select a compatible default python interpreter"
	local x success=0
	for x in /usr/bin/python2.* ; do
	x=${x#/usr/bin/python2.}
	if [[ $x -ge 6 ]] 2>/dev/null ; then
	eselect python set python2.$x
	if compatible_python_is_selected ; then
	elog "Default python interpreter is now set to python-2.$x"
	success=1
	break
	fi
	fi
	done
	if [ $success != 1 ] ; then
	eerror "Unable to select a compatible default python interpreter!"
	die "This version of portage requires at least python-2.6 to be selected as the default python interpreter (see \`eselect python --help\`)."
	fi
	fi
	}

	src_prepare() {
	if [ -n "${PATCHVER}" ] ; then
	if [[ -L $S/bin/ebuild-helpers/portageq ]] ; then
	rm "$S/bin/ebuild-helpers/portageq" \
	\|\| die "failed to remove portageq helper symlink"
	fi
	epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
	fi
	einfo "Setting portage.VERSION to ${PVR} ..."
	sed -i "s/^VERSION=.*/VERSION=\"${PVR}\"/" pym/portage/__init__.py \|\| \
	die "Failed to patch portage.VERSION"

	if use python3; then
	python_convert_shebangs -r 3 .
	fi
	}

	src_compile() {
	if use doc; then
	cd "${S}"/doc
	touch fragment/date
	make xhtml xhtml-nochunks \|\| die "failed to make docs"
	fi

	if use epydoc; then
	einfo "Generating api docs"
	mkdir "${WORKDIR}"/api
	local my_modules epydoc_opts=""
	# A name collision between the portage.dbapi class and the
	# module with the same name triggers an epydoc crash unless
	# portage.dbapi is excluded from introspection.
	ROOT=/ has_version '>=dev-python/epydoc-3_pre0' && \
	epydoc_opts='--exclude-introspect portage\.dbapi'
	my_modules="$(find "${S}/pym" -name "*.py" \
	\| sed -e 's:/__init__.py$::' -e 's:\.py$::' -e "s:^${S}/pym/::" \
	-e 's:/:.:g' \| sort)" \|\| die "error listing modules"
	# workaround for bug 282760
	> "$S/pym/pysqlite2.py"
	PYTHONPATH=${S}/pym:${PYTHONPATH:+:}${PYTHONPATH} \
	epydoc -o "${WORKDIR}"/api \
	-qqqqq --no-frames --show-imports $epydoc_opts \
	--name "${PN}" --url "${HOMEPAGE}" \
	${my_modules} \|\| die "epydoc failed"
	rm "$S/pym/pysqlite2.py"
	fi
	}

	src_test() {
	PYTHONPATH=${S}/pym:${PYTHONPATH:+:}${PYTHONPATH} \
	./pym/portage/tests/runTests \|\| die "test(s) failed"
	}

	src_install() {
	local libdir=$(get_libdir)
	local portage_base="/usr/${libdir}/portage"
	local portage_share_config=/usr/share/portage/config

	cd "${S}"/cnf
	insinto /etc
	doins etc-update.conf dispatch-conf.conf \|\| die

	dodir "${portage_share_config}"
	insinto "${portage_share_config}"
	doins "${S}/cnf/make.globals" \|\| die
	if [ -f "make.conf.${ARCH}".diff ]; then
	patch make.conf "make.conf.${ARCH}".diff \|\| \
	die "Failed to patch make.conf.example"
	newins make.conf make.conf.example \|\| die
	else
	eerror ""
	eerror "Portage does not have an arch-specific configuration for this arch."
	eerror "Please notify the arch maintainer about this issue. Using generic."
	eerror ""
	newins make.conf make.conf.example \|\| die
	fi

	dosym ..${portage_share_config}/make.globals /etc/make.globals

	insinto /etc/logrotate.d
	doins "${S}"/cnf/logrotate.d/elog-save-summary \|\| die

	# BSD and OSX need a sed wrapper so that find/xargs work properly
	if use userland_GNU; then
	rm "${S}"/bin/ebuild-helpers/sed \|\| die "Failed to remove sed wrapper"
	fi

	local x symlinks

	# current tarball contains outdated stuff
	rm -rf "$S"/bin/ebuild-helpers/3
	for x in dohard dosed ; do
	dosym ../../banned-helper ${portage_base}/bin/ebuild-helpers/4/$x
	done

	for x in $(find "$S"/bin -type d) ; do
	x=${x#$S/}
	exeinto $portage_base/$x \|\| die "exeinto failed"
	cd "$S"/$x \|\| die "cd failed"
	doexe $(find . -mindepth 1 -maxdepth 1 -type f ! -type l) \|\| \
	die "doexe failed"
	symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
	if [ -n "$symlinks" ] ; then
	cp -P $symlinks "$D$portage_base/$x" \|\| die "cp failed"
	fi
	done

	for x in $(find "$S"/pym -type d) ; do
	x=${x#$S/}
	insinto $portage_base/$x \|\| die "insinto failed"
	cd "$S"/$x \|\| die "cd failed"
	doins *.py \|\| die "doins failed"
	symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
	if [ -n "$symlinks" ] ; then
	cp -P $symlinks "$D$portage_base/$x" \|\| die "cp failed"
	fi
	done

	# Symlinks to directories cause up/downgrade issues and the use of these
	# modules outside of portage is probably negligible.
	for x in "${D}${portage_base}/pym/"{cache,elog_modules} ; do
	[ ! -L "${x}" ] && continue
	die "symlink to directory will cause upgrade/downgrade issues: '${x}'"
	done

	exeinto ${portage_base}/pym/portage/tests
	doexe "${S}"/pym/portage/tests/runTests

	doman "${S}"/man/*.[0-9]
	if use linguas_pl; then
	doman -i18n=pl "${S_PL}"/man/pl/*.[0-9]
	doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9]
	fi

	dodoc "${S}"/{ChangeLog,NEWS,RELEASE-NOTES}
	use doc && dohtml -r "${S}"/doc/*
	use epydoc && dohtml -r "${WORKDIR}"/api

	dodir /usr/bin
	for x in ebuild egencache emerge portageq repoman ; do
	dosym ../${libdir}/portage/bin/${x} /usr/bin/${x}
	done

	dodir /usr/sbin
	local my_syms="archive-conf
	dispatch-conf
	emaint
	emerge-webrsync
	env-update
	etc-update
	fixpackages
	quickpkg
	regenworld"
	local x
	for x in ${my_syms}; do
	dosym ../${libdir}/portage/bin/${x} /usr/sbin/${x}
	done
	dosym env-update /usr/sbin/update-env
	dosym etc-update /usr/sbin/update-etc

	dodir /etc/portage
	keepdir /etc/portage
	}

	pkg_preinst() {
	if ! use build && ! has_version dev-python/pycrypto && \
	! has_version '>=dev-lang/python-2.6[ssl]' ; then
	ewarn "If you are an ebuild developer and you plan to commit ebuilds"
	ewarn "with this system then please install dev-python/pycrypto or"
	ewarn "enable the ssl USE flag for >=dev-lang/python-2.6 in order"
	ewarn "to enable RMD160 hash support."
	ewarn "See bug #198398 for more information."
	fi
	if [ -f "${ROOT}/etc/make.globals" ]; then
	rm "${ROOT}/etc/make.globals"
	fi

	[[ -n $PORTDIR_OVERLAY ]] && has_version "<${CATEGORY}/${PN}-2.1.6.12"
	REPO_LAYOUT_CONF_WARN=$?
	has_version "<${CATEGORY}/${PN}-2.1.7"
	UPGRADE_FROM_2_1=$?
	}

	pkg_postinst() {
	# Compile all source files recursively. Any orphans
	# will be identified and removed in postrm.
	python_mod_optimize /usr/$(get_libdir)/portage/pym

	local warning_shown=0
	if [ $REPO_LAYOUT_CONF_WARN = 0 ] ; then
	ewarn
	echo "If you want overlay eclasses to override eclasses from" \
	"other repos then see the portage(5) man page" \
	"for information about the new layout.conf and repos.conf" \
	"configuration files." \
	\| fmt -w 75 \| while read -r ; do ewarn "$REPLY" ; done
	fi
	if [[ $UPGRADE_FROM_2_1 = 0 && -n $PORTAGE_BINHOST ]] ; then
	ewarn
	echo "If you have an old PORTAGE_BINHOST setting in /etc/make.conf" \
	"then you will encounter bug #303211. Therefore, please ensure" \
	"that your PORTAGE_BINHOST setting points to a remote directory" \
	"containing a \$PKGDIR/Packages file which is created by" \
	">=portage-2.1.6. If \$PKGDIR/Packages does not exist on" \
	"the server or it is incomplete, you must run \`emaint" \
	"--fix binhost\` on the server in order to generate it." \
	"See \`man make.conf\` for more information about" \
	"PORTAGE_BINHOST." \| \
	fmt -w 70 \| while read -r ; do ewarn "$REPLY" ; done
	warning_shown=1
	fi
	if [ $warning_shown = 1 ] ; then
	ewarn # for symmetry
	fi

	einfo
	einfo "For help with using portage please consult the Gentoo Handbook"
	einfo "at http://www.gentoo.org/doc/en/handbook/handbook-x86.xml?part=3"
	einfo
	}

	pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/portage/pym
	}