chrome/browser/resources/settings_shared/BUILD.gn

# Copyright 2023 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ui/webui/resources/tools/build_webui.gni")

assert(!is_android)

build_webui("build") {
  grd_prefix = "settings_shared"
  grd_resource_path_prefix = "shared/settings"

  web_component_files = [
    "controls/controlled_button.ts",
    "controls/controlled_radio_button.ts",
    "controls/extension_controlled_indicator.ts",
    "controls/settings_dropdown_menu.ts",
    "controls/settings_radio_group.ts",
    "controls/settings_slider.ts",
    "controls/settings_toggle_button.ts",
    "privacy_page/secure_dns.ts",
    "privacy_page/secure_dns_input.ts",
  ]

  if (is_chromeos) {
    web_component_files += [ "controls/password_prompt_dialog.ts" ]
  }

  non_web_component_files = [
    "extension_control_browser_proxy.ts",
    "lifetime_browser_proxy.ts",

    "a11y_page/captions_browser_proxy.ts",
    "appearance_page/fonts_browser_proxy.ts",
    "controls/cr_policy_pref_mixin.ts",
    "controls/pref_control_mixin.ts",
    "controls/settings_boolean_control_mixin.ts",
    "people_page/profile_info_browser_proxy.ts",
    "people_page/sync_browser_proxy.ts",
    "privacy_page/privacy_page_browser_proxy.ts",
  ]

  ts_composite = true
  ts_definitions = [
    "//tools/typescript/definitions/chrome_send.d.ts",
    "//tools/typescript/definitions/metrics_private.d.ts",
    "//tools/typescript/definitions/settings_private.d.ts",
  ]
  if (is_chromeos) {
    ts_definitions += [
      "//tools/typescript/definitions/tabs.d.ts",
      "//tools/typescript/definitions/runtime.d.ts",
      "//tools/typescript/definitions/quick_unlock_private.d.ts",
    ]
  }
  ts_deps = [
    "//third_party/polymer/v3_0:library",
    "//ui/webui/resources/cr_components/settings_prefs:build_ts",
    "//ui/webui/resources/cr_elements:build_ts",
    "//ui/webui/resources/js:build_ts",
  ]
}