Tests/RunCMake/File_Archive/roundtrip.cmake

foreach(parameter OUTPUT_NAME ARCHIVE_FORMAT)
  if(NOT DEFINED ${parameter})
    message(FATAL_ERROR "missing required parameter ${parameter}")
  endif()
endforeach()

set(COMPRESS_DIR compress_dir)
set(FULL_COMPRESS_DIR ${CMAKE_CURRENT_BINARY_DIR}/${COMPRESS_DIR})

set(DECOMPRESS_DIR decompress_dir)
set(FULL_DECOMPRESS_DIR ${CMAKE_CURRENT_BINARY_DIR}/${DECOMPRESS_DIR})

set(FULL_OUTPUT_NAME ${CMAKE_CURRENT_BINARY_DIR}/${OUTPUT_NAME})

set(CHECK_FILES
  "f1.txt"
  "d1/f1.txt"
  "d 2/f1.txt"
  "d + 3/f1.txt"
  "d_4/f1.txt"
  "d-4/f1.txt"
  "My Special Directory/f1.txt"
  ${COMPRESSION_ADDITIONAL_FILE_NAMES}
)

foreach(file ${CHECK_FILES})
  configure_file(${CMAKE_CURRENT_LIST_FILE} ${FULL_COMPRESS_DIR}/${file} COPYONLY)
endforeach()

# Test a (file) symlink inside the archive on platforms which support it.
execute_process(
  COMMAND ${CMAKE_COMMAND} -E create_symlink f1.txt ${FULL_COMPRESS_DIR}/d1/f2.txt
  OUTPUT_VARIABLE create_symlink_stdout
  ERROR_VARIABLE create_symlink_stderr
  RESULT_VARIABLE create_symlink_result
)
if(create_symlink_result EQUAL 0 AND EXISTS "${FULL_COMPRESS_DIR}/d1/f2.txt")
  list(APPEND CHECK_FILES "d1/f2.txt")
endif()

file(REMOVE ${FULL_OUTPUT_NAME})
file(REMOVE_RECURSE ${FULL_DECOMPRESS_DIR})
if(DESTINATION_SYMLINK)
  # If specified, test extraction to a directory symlink on platforms which
  # support it, but fall back to a plain directory otherwise.
  cmake_policy(SET CMP0205 NEW)
  file(MAKE_DIRECTORY ${FULL_DECOMPRESS_DIR}-dir)
  file(CREATE_LINK
    ${FULL_DECOMPRESS_DIR}-dir ${FULL_DECOMPRESS_DIR}
    COPY_ON_ERROR
    SYMBOLIC
  )
else()
  file(MAKE_DIRECTORY ${FULL_DECOMPRESS_DIR})
endif()

set(ENCODING_OPTIONS "")
if (ENCODING)
  set(ENCODING_OPTIONS ENCODING "${ENCODING}")
endif()

file(ARCHIVE_CREATE
  OUTPUT ${FULL_OUTPUT_NAME}
  FORMAT "${ARCHIVE_FORMAT}"
  COMPRESSION "${COMPRESSION_TYPE}"
  WORKING_DIRECTORY "${WORKING_DIRECTORY}"
  ${ENCODING_OPTIONS}
  VERBOSE
  PATHS ${FULL_COMPRESS_DIR})

file(ARCHIVE_EXTRACT
  INPUT ${FULL_OUTPUT_NAME}
  ${ENCODING_OPTIONS}
  ${DECOMPRESSION_OPTIONS}
  DESTINATION ${FULL_DECOMPRESS_DIR}
  VERBOSE)

if(CUSTOM_CHECK_FILES)
  set(CHECK_FILES ${CUSTOM_CHECK_FILES})
endif()

foreach(file ${CHECK_FILES})
  set(input ${FULL_COMPRESS_DIR}/${file})
  set(output ${FULL_DECOMPRESS_DIR}/${CUSTOM_OUTPUT_DIRECTORY}/${COMPRESS_DIR}/${file})

  if(NOT EXISTS ${input})
    message(SEND_ERROR "Cannot find input file:\n  \"${output}\"")
  endif()

  if(NOT EXISTS ${output})
    message(SEND_ERROR "Cannot find output file:\n  \"${output}\"")
  endif()

  file(MD5 ${input} input_md5)
  file(MD5 ${output} output_md5)

  if(NOT input_md5 STREQUAL output_md5)
    message(SEND_ERROR
      "Files:\n"
      "  \"${input}\"\n"
      "and\n"
      "  \"${output}\"\n"
      "are different"
    )

  endif()
endforeach()

foreach(file ${NOT_EXISTING_FILES_CHECK})
  set(output ${FULL_DECOMPRESS_DIR}/${COMPRESS_DIR}/${file})

  if(EXISTS ${output})
    message(SEND_ERROR "File exists but it shouldn't:\n  \"${output}\"")
  endif()
endforeach()

function(check_magic EXPECTED)
  file(READ ${FULL_OUTPUT_NAME} ACTUAL
    ${ARGN}
  )

  if(EXPECTED MATCHES "[^0-9a-f]" AND ACTUAL MATCHES "${EXPECTED}")
    return()
  endif()

  if(NOT ACTUAL STREQUAL EXPECTED)
    message(FATAL_ERROR
      "Actual [${ACTUAL}] does not match expected [${EXPECTED}]")
  endif()
endfunction()