Source/cmake/WebKitVersion.cmake

set(_version_xcconfig "${CMAKE_SOURCE_DIR}/Configurations/Version.xcconfig")
if (EXISTS "${_version_xcconfig}")
    file(STRINGS "${_version_xcconfig}" _version_lines)
    foreach (_line IN LISTS _version_lines)
        if (_line MATCHES "^MAJOR_VERSION = ([0-9]+)")
            set(_major "${CMAKE_MATCH_1}")
        elseif (_line MATCHES "^MINOR_VERSION = ([0-9]+)")
            set(_minor "${CMAKE_MATCH_1}")
        elseif (_line MATCHES "^TINY_VERSION = ([0-9]+)")
            set(_tiny "${CMAKE_MATCH_1}")
        endif ()
    endforeach ()
    if (DEFINED _major AND DEFINED _minor AND DEFINED _tiny)
        set(WEBKIT_MAC_VERSION "${_major}.${_minor}.${_tiny}")
        set(MACOSX_FRAMEWORK_BUNDLE_VERSION "${_major}.${_minor}.${_tiny}+")
    else ()
        message(WARNING "Version.xcconfig found but could not parse MAJOR/MINOR/TINY_VERSION")
        set(WEBKIT_MAC_VERSION 620.0.0)
        set(MACOSX_FRAMEWORK_BUNDLE_VERSION 620.0.0+)
    endif ()
    unset(_version_lines)
    unset(_major)
    unset(_minor)
    unset(_tiny)
    unset(_line)
else ()
    message(WARNING "Configurations/Version.xcconfig not found, using fallback version")
    set(WEBKIT_MAC_VERSION 620.0.0)
    set(MACOSX_FRAMEWORK_BUNDLE_VERSION 620.0.0+)
endif ()
unset(_version_xcconfig)