chrome/browser/password_entry_edit/android/BUILD.gn

# Copyright 2021 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//chrome/android/features/android_library_factory_tmpl.gni")

source_set("android") {
  sources = [
    "credential_edit_bridge.cc",
    "credential_edit_bridge.h",
  ]

  deps = [
    ":jni_headers",
    "//base",
    "//chrome/app:generated_resources",
    "//chrome/browser/ui",
    "//components/password_manager/core/browser",
    "//components/password_manager/core/browser:affiliation",
    "//components/url_formatter",
    "//ui/base",
  ]
}

generate_jni("jni_headers") {
  sources = [ "internal/java/src/org/chromium/chrome/browser/password_entry_edit/CredentialEditBridge.java" ]
}

android_library("java") {
  sources = [
    "//chrome/browser/password_entry_edit/android/java/src/org/chromium/chrome/browser/password_entry_edit/BlockedCredentialFragmentView.java",
    "//chrome/browser/password_entry_edit/android/java/src/org/chromium/chrome/browser/password_entry_edit/CredentialEditFragmentView.java",
    "//chrome/browser/password_entry_edit/android/java/src/org/chromium/chrome/browser/password_entry_edit/CredentialEntryFragmentViewBase.java",
    "//chrome/browser/password_entry_edit/android/java/src/org/chromium/chrome/browser/password_entry_edit/FederatedCredentialFragmentView.java",
  ]

  deps = [
    ":java_resources",
    "//third_party/android_deps:material_design_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_core_core_java",
    "//third_party/androidx:androidx_preference_preference_java",
    "//ui/android:ui_no_recycler_view_java",
  ]

  resources_package = "org.chromium.chrome.browser.password_entry_edit"
}

android_resources("java_resources") {
  sources = [
    "java/res/layout/blocked_credential_view.xml",
    "java/res/layout/credential_edit_view.xml",
    "java/res/layout/federated_credential_view.xml",
    "java/res/layout/site_or_app.xml",
    "java/res/menu/credential_edit_action_bar_menu.xml",
    "java/res/values/dimens.xml",
  ]
  deps = [
    "//chrome/browser/feedback/android:java_resources",
    "//chrome/browser/ui/android/strings:ui_strings_grd",
    "//components/browser_ui/styles/android:java_resources",
    "//components/browser_ui/widget/android:java_resources",
  ]
}

android_library_factory("factory_java") {
  # These deps will be inherited by the resulting android_library target.
  deps = [
    ":java",
    "//chrome/browser/feedback/android:java",
  ]

  # This internal file will be replaced by a generated file so the resulting
  # android_library target does not actually depend on this internal file.
  sources = [ "//chrome/browser/password_entry_edit/android/internal/java/src/org/chromium/chrome/browser/password_entry_edit/CredentialEditUiFactory.java" ]
}