components/autofill/ios/browser/BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/web/js_compile.gni")

source_set("browser") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "autofill_agent.h",
    "autofill_agent.mm",
    "autofill_client_ios_bridge.h",
    "autofill_driver_ios.h",
    "autofill_driver_ios.mm",
    "autofill_driver_ios_bridge.h",
    "autofill_util.h",
    "autofill_util.mm",
    "credit_card_util.h",
    "credit_card_util.mm",
    "form_suggestion.h",
    "form_suggestion.mm",
    "form_suggestion_provider.h",
    "js_autofill_manager.h",
    "js_autofill_manager.mm",
    "js_suggestion_manager.h",
    "js_suggestion_manager.mm",
    "personal_data_manager_observer_bridge.h",
    "personal_data_manager_observer_bridge.mm",
  ]

  deps = [
    ":injected_js",
    "//base",
    "//components/autofill/core/browser",
    "//components/autofill/core/common",
    "//components/prefs:prefs",
    "//google_apis",
    "//ios/web",
    "//ui/gfx/geometry",
  ]
}

source_set("test_support") {
  testonly = true
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "fake_autofill_agent.h",
    "fake_autofill_agent.mm",
    "fake_js_autofill_manager.h",
    "fake_js_autofill_manager.mm",
  ]
  public_deps = [
    ":browser",
  ]
  deps = [
    "//base",
    "//ios/web/public",
  ]
}

js_compile_checked("injected_js") {
  visibility = [ ":browser" ]
  sources = [
    "resources/suggestion_controller.js",
  ]
}

source_set("unit_tests") {
  testonly = true
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "autofill_agent_unittests.mm",
  ]
  deps = [
    ":browser",
    "//base",
    "//components/autofill/core/browser:test_support",
    "//components/prefs",
    "//ios/web/public",
    "//ios/web/public/test/fakes",
    "//testing/gmock",
    "//testing/gtest",
    "//third_party/ocmock",
  ]
}