components/security_interstitials/core/BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

static_library("core") {
  sources = [
    "bad_clock_ui.cc",
    "bad_clock_ui.h",
    "base_safe_browsing_error_ui.cc",
    "base_safe_browsing_error_ui.h",
    "blocked_interception_ui.cc",
    "blocked_interception_ui.h",
    "common_string_util.cc",
    "common_string_util.h",
    "controller_client.cc",
    "controller_client.h",
    "features.cc",
    "features.h",
    "legacy_tls_ui.cc",
    "legacy_tls_ui.h",
    "metrics_helper.cc",
    "metrics_helper.h",
    "mitm_software_ui.cc",
    "mitm_software_ui.h",
    "pref_names.cc",
    "pref_names.h",
    "safe_browsing_loud_error_ui.cc",
    "safe_browsing_loud_error_ui.h",
    "safe_browsing_quiet_error_ui.cc",
    "safe_browsing_quiet_error_ui.h",
    "ssl_error_options_mask.cc",
    "ssl_error_options_mask.h",
    "ssl_error_ui.cc",
    "ssl_error_ui.h",
    "urls.cc",
    "urls.h",
  ]

  if (is_ios) {
    sources -= [
      "blocked_interception_ui.cc",
      "blocked_interception_ui.h",
      "mitm_software_ui.cc",
      "mitm_software_ui.h",
    ]
  }

  deps = [
    "//base",
    "//base:i18n",
    "//components/google/core/common",
    "//components/history/core/browser",
    "//components/metrics",
    "//components/prefs",
    "//components/resources",
    "//components/ssl_errors",
    "//components/strings",
    "//components/url_formatter",
    "//net",
    "//third_party/zlib/google:compression_utils",
    "//ui/base",
  ]

  public_deps = [ "//components/security_interstitials/core/common/mojom" ]
}

static_library("unsafe_resource") {
  sources = [
    "unsafe_resource.cc",
    "unsafe_resource.h",
  ]

  deps = [
    "//base",
    "//components/safe_browsing/core/common:common",
    "//components/safe_browsing/core/db:hit_report",
    "//components/safe_browsing/core/db:util",
    "//net",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "ssl_error_options_mask_unittest.cc" ]

  deps = [
    ":core",
    "//base",
    "//net",
    "//testing/gtest",
  ]
}