device/vibration/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")
import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")

component("vibration") {
  output_name = "device_vibration"

  sources = [
    "vibration_export.h",
    "vibration_manager_impl.h",
    "vibration_manager_impl_android.cc",
    "vibration_manager_impl_android.h",
    "vibration_manager_impl_default.cc",
  ]

  defines = [ "DEVICE_VIBRATION_IMPLEMENTATION" ]

  deps = [
    ":mojo_bindings",
    "//base",
    "//base/third_party/dynamic_annotations",
    "//mojo/environment:chromium",
    "//third_party/mojo/src/mojo/public/cpp/bindings",
    "//third_party/mojo/src/mojo/edk/system",
  ]

  if (is_android) {
    sources -= [ "vibration_manager_impl_default.cc" ]
    deps += [
      "//device/vibration/android",
      "//device/vibration/android:vibration_jni_headers",
    ]
    allow_circular_includes_from = [ "//device/vibration/android" ]
  }
}

mojom("mojo_bindings") {
  sources = [
    "vibration_manager.mojom",
  ]
}