chrome/browser/resources/new_tab_footer/BUILD.gn

# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ui/webui/resources/tools/build_webui.gni")

assert(!is_android)

build_webui("build") {
  grd_prefix = "new_tab_footer"

  static_files = [ "new_tab_footer.html" ]

  ts_files = [
    "app.ts",
    "app.html.ts",
    "browser_proxy.ts",
    "customize_buttons_proxy.ts",
    "window_proxy.ts",
  ]
  css_files = [ "app.css" ]

  webui_context_type = "trusted"

  ts_composite = true
  ts_definitions = [ "//tools/typescript/definitions/metrics_private.d.ts" ]
  ts_deps = [
    "//chrome/browser/resources/new_tab_shared:build_ts",
    "//third_party/lit/v3_0:build_ts",
    "//ui/webui/resources/cr_components/color_change_listener:build_ts",
    "//ui/webui/resources/cr_components/help_bubble:build_ts",
    "//ui/webui/resources/cr_elements:build_ts",
    "//ui/webui/resources/js:build_ts",
    "//ui/webui/resources/mojo:build_ts",
  ]

  mojo_files_deps = [
    "//chrome/browser/ui/webui/customize_buttons:mojo_bindings_ts__generator",
    "//chrome/browser/ui/webui/new_tab_footer:mojo_bindings_ts__generator",
    "//chrome/browser/ui/webui/side_panel/customize_chrome:mojo_bindings_ts__generator",
  ]
  mojo_files = [
    "$root_gen_dir/chrome/browser/ui/webui/customize_buttons/customize_buttons.mojom-webui.ts",
    "$root_gen_dir/chrome/browser/ui/webui/new_tab_footer/new_tab_footer.mojom-webui.ts",
    "$root_gen_dir/chrome/browser/ui/webui/side_panel/customize_chrome/customize_chrome.mojom-webui.ts",
  ]

  ts_path_mappings =
      [ "chrome://newtab-footer/shared/*|" +
        rebase_path(
            "$root_gen_dir/chrome/browser/resources/new_tab_shared/tsc/*",
            target_gen_dir) ]
}