chrome/browser/ui/bookmarks/BUILD.gn

# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_win || is_mac || is_linux || is_chromeos)

source_set("bookmarks") {
  sources = [
    "bookmark_bar.h",
    "bookmark_bar_controller.h",
    "bookmark_context_menu_controller.h",
    "bookmark_drag_drop.h",
    "bookmark_editor.h",
    "bookmark_stats.h",
    "bookmark_stats_tab_helper.h",
    "bookmark_tab_helper.h",
    "bookmark_tab_helper_observer.h",
    "bookmark_ui_operations_helper.h",
    "bookmark_utils.h",
    "bookmark_utils_desktop.h",
    "recently_used_folders_combo_model.h",
    "test_bookmark_navigation_wrapper.h",
  ]

  public_deps = [
    "//base",
    "//chrome/browser/ui/tabs:tab_strip_model_observer",
    "//components/bookmarks/browser",
    "//components/page_load_metrics/browser",
    "//components/prefs",
    "//components/profile_metrics",
    "//components/tab_groups",
    "//content/public/browser",
    "//skia",
    "//ui/base",
    "//ui/base/dragdrop/mojom",
    "//ui/base/unowned_user_data",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//ui/menus",
    "//url",
  ]
}

source_set("impl") {
  public_deps = [ "//chrome/browser:browser_public_dependencies" ]

  sources = [
    "bookmark_bar_controller.cc",
    "bookmark_context_menu_controller.cc",
    "bookmark_drag_drop.cc",
    "bookmark_editor.cc",
    "bookmark_stats.cc",
    "bookmark_stats_tab_helper.cc",
    "bookmark_tab_helper.cc",
    "bookmark_ui_operations_helper.cc",
    "bookmark_utils.cc",
    "bookmark_utils_desktop.cc",
    "recently_used_folders_combo_model.cc",
    "test_bookmark_navigation_wrapper.cc",
  ]

  deps = [
    ":bookmarks",
    "//chrome/app:command_ids",
    "//chrome/browser/prefs",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/search",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui:browser_navigator_params_headers",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/tabs:tab_group",
    "//chrome/browser/ui/tabs:tab_strip",
    "//chrome/browser/ui/tabs/saved_tab_groups",
    "//components/bookmarks/common",
    "//components/bookmarks/managed",
    "//components/saved_tab_groups/public:features",
    "//components/search",
    "//components/sync_preferences",
    "//components/undo",
    "//components/user_prefs",
  ]

  if (is_mac) {
    deps += [ "//chrome/browser/web_applications" ]
  }
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [ "bookmark_browsertest.cc" ]

  deps = [
    ":bookmarks",
    "//base",
    "//base/test:test_support",
    "//chrome/app:command_ids",
    "//chrome/browser",
    "//chrome/browser:browser_process",
    "//chrome/browser:primitives",
    "//chrome/browser:test_support",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui",
    "//chrome/browser/ui:browser_list",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/tabs:tab_strip",
    "//chrome/browser/ui/tabs/saved_tab_groups",
    "//chrome/common",
    "//chrome/test:test_support_ui",
    "//components/bookmarks/browser",
    "//components/bookmarks/test",
    "//components/saved_tab_groups/public",
    "//components/security_interstitials/content:security_interstitial_page",
    "//content/public/browser",
    "//content/test:test_support",
    "//net:test_support",
    "//testing/gmock",
    "//ui/base",
    "//ui/base:features",
    "//ui/base/dragdrop/mojom",
    "//ui/gfx",
    "//ui/views:test_support",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "bookmark_context_menu_controller_unittest.cc",
    "bookmark_editor_unittest.cc",
    "bookmark_stats_tab_helper_unittest.cc",
    "bookmark_ui_operations_helper_unittest.cc",
    "bookmark_ui_utils_desktop_unittest.cc",
    "bookmark_unittest.cc",
    "bookmark_utils_unittest.cc",
    "recently_used_folders_combo_model_unittest.cc",
  ]

  deps = [
    ":bookmarks",
    "//base",
    "//base/test:test_support",
    "//chrome/app:command_ids",
    "//chrome/browser",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/browser_window",
    "//chrome/common",
    "//chrome/test:test_support",
    "//components/bookmarks/browser",
    "//components/bookmarks/common",
    "//components/bookmarks/managed",
    "//components/bookmarks/test",
    "//components/dom_distiller/core",
    "//components/saved_tab_groups/public:features",
    "//components/saved_tab_groups/test_support",
    "//components/sync_preferences:test_support",
    "//content/public/browser",
    "//content/test:test_support",
    "//testing/gtest",
    "//ui/base",
    "//ui/base/clipboard",
    "//ui/base/clipboard:clipboard_test_support",
    "//url",
  ]
}