chrome/browser/ui/webui/side_panel/customize_chrome/BUILD.gn

# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

assert(!is_android)

mojom("mojo_bindings") {
  sources = [
    "customize_chrome.mojom",
    "customize_toolbar/customize_toolbar.mojom",
    "wallpaper_search/wallpaper_search.mojom",
  ]
  public_deps = [
    "//components/ntp_tiles:mojo_bindings",
    "//mojo/public/mojom/base",
    "//skia/public/mojom",
    "//url/mojom:url_mojom_gurl",
  ]

  webui_module_path = "/"

  cpp_typemaps = [
    {
      types = [
        {
          mojom = "side_panel.mojom.CustomizeChromeSection"
          cpp = "::CustomizeChromeSection"
        },
      ]
      traits_headers = [ "customize_chrome_mojom_traits.h" ]
      traits_public_deps = [ ":mojom_traits" ]
    },
  ]
}

source_set("customize_chrome") {
  sources = [ "customize_chrome_section.h" ]
}

source_set("mojom_traits") {
  sources = [ "customize_chrome_mojom_traits.h" ]

  deps = [ ":customize_chrome" ]

  public_deps = [
    ":mojo_bindings_shared_cpp_sources",
    "//base",
  ]
}