components/content_relationship_verification/BUILD.gn

# Copyright 2021 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("content_relationship_verification") {
  sources = [
    "digital_asset_links_handler.cc",
    "digital_asset_links_handler.h",
    "response_header_verifier.cc",
    "response_header_verifier.h",
  ]

  deps = [
    "//base",
    "//content/public/browser",
    "//content/public/common",
    "//net",
    "//services/data_decoder/public/cpp",
    "//services/network/public/cpp",
    "//url",
  ]
  if (is_android) {
    sources += [
      "origin_verifier.cc",
      "origin_verifier.h",
    ]
    deps +=
        [ "//components/content_relationship_verification/android:jni_headers" ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "digital_asset_links_handler_unittest.cc",
    "response_header_verifier_unittest.cc",
  ]

  deps = [
    ":content_relationship_verification",
    "//base",
    "//content/test:test_support",
    "//net",
    "//services/data_decoder/public/cpp:test_support",
    "//services/network:test_support",
    "//testing/gtest",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}

if (is_android) {
  import("//build/config/android/rules.gni")

  android_library("java") {
    deps = [ "//third_party/androidx:androidx_annotation_annotation_java" ]
    srcjar_deps =
        [ "//components/content_relationship_verification:enums_srcjar" ]
  }

  java_cpp_enum("enums_srcjar") {
    sources = [ "digital_asset_links_handler.h" ]
  }
}