mash/app_driver/BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")
import("//services/shell/public/cpp/service.gni")
import("//services/shell/public/service_manifest.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//tools/grit/repack.gni")

source_set("lib") {
  sources = [
    "app_driver.cc",
    "app_driver.h",
  ]

  deps = [
    "//mash/public/interfaces",
    "//services/ui/common:mus_common",
  ]

  public_deps = [
    "//base",
    "//services/catalog/public/interfaces",
    "//services/shell/public/cpp:sources",
    "//services/ui/public/interfaces",
  ]

  data_deps = [
    "//services/ui",
  ]
}

service("app_driver") {
  sources = [
    "main.cc",
  ]

  deps = [
    ":lib",
    "//base",
    "//mojo/public/cpp/bindings",
    "//services/shell/public/cpp",
    "//services/shell/public/cpp:sources",
  ]

  data_deps = [
    ":manifest",
    "//ash/touch_hud/mus:touch_hud",
    "//mash/task_viewer",
  ]
}

service_manifest("manifest") {
  name = "app_driver"
  source = "manifest.json"
}