| # Copyright 2017 The Chromium Authors. All rights reserved. |
| # Use of this source code is governed by a BSD-style license that can be |
| # found in the LICENSE file. |
| |
| import("//build/config/ui.gni") |
| import("//components/viz/viz.gni") |
| import("//testing/test.gni") |
| |
| viz_test("viz_unittests") { |
| use_xvfb = use_xvfb_in_this_config |
| |
| sources = [ "test/run_all_unittests.cc" ] |
| deps = [ |
| "//base", |
| "//base/test:test_support", |
| "//components/viz/client:unit_tests", |
| "//components/viz/common:unit_tests", |
| "//components/viz/host:unit_tests", |
| "//components/viz/service:unit_tests", |
| "//components/viz/test:test_suite", |
| "//components/viz/test:test_support", |
| "//components/viz/test:unit_tests", |
| "//mojo/core/embedder", |
| ] |
| |
| data = [ "test/data/" ] |
| |
| data_deps = [ |
| "//testing/buildbot/filters:viz_unittests_filters", |
| "//third_party/mesa_headers", |
| ] |
| |
| if (is_android) { |
| # The top level test target must depend on the java library directly. |
| deps += [ "//components/viz/service:service_java" ] |
| } |
| |
| if (is_fuchsia) { |
| additional_manifest_fragments = [ |
| # TODO(crbug.com/1185811): Figure out why jit_capabilities is needed. |
| "//build/config/fuchsia/test/jit_capabilities.test-cmx", |
| |
| "//build/config/fuchsia/test/vulkan_capabilities.test-cmx", |
| ] |
| } |
| } |
| |
| viz_test("viz_perftests") { |
| sources = [ "test/run_all_perftests.cc" ] |
| |
| deps = [ |
| "//base", |
| "//base/test:test_support", |
| "//components/viz/common:perf_tests", |
| "//components/viz/service:perf_tests", |
| "//components/viz/test:test_suite", |
| "//components/viz/test:test_support", |
| "//mojo/core/embedder", |
| "//skia", |
| ] |
| |
| data = [ "test/data/" ] |
| |
| # This target should not require the Chrome executable to run. |
| assert_no_deps = [ "//chrome" ] |
| |
| data_deps = [ |
| # Needed for isolate script to execute. |
| "//testing:run_perf_test", |
| ] |
| } |
| |
| if (is_android) { |
| java_cpp_features("java_features_srcjar") { |
| # External code should depend on ":viz_java" instead. |
| visibility = [ ":*" ] |
| sources = [ "common/features.cc" ] |
| template = "common/java/src/org/chromium/components/viz/common/VizFeatures.java.tmpl" |
| } |
| |
| android_library("viz_java") { |
| # Right now, this only includes the Java features. But if we need more Java |
| # files, they should be added here as necessary. |
| srcjar_deps = [ ":java_features_srcjar" ] |
| } |
| } |