chrome/browser/contextual_tasks/BUILD.gn

# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("contextual_tasks") {
  sources = [
    "contextual_tasks_context_controller_factory.cc",
    "contextual_tasks_context_controller_factory.h",
    "contextual_tasks_service_factory.cc",
    "contextual_tasks_service_factory.h",
  ]

  deps = [
    ":internal",
    "//base",
    "//components/contextual_tasks/internal",
    "//components/contextual_tasks/public",
    "//content/public/browser",
  ]

  public_deps = [
    ":public",
    "//chrome/browser/profiles:profile",
  ]
}

source_set("public") {
  sources = [
    "contextual_tasks_context_controller.cc",
    "contextual_tasks_context_controller.h",
  ]

  deps = [
    "//base",
    "//components/contextual_tasks/public",
    "//components/keyed_service/core",
  ]
}

source_set("internal") {
  visibility = [ ":*" ]

  sources = [
    "contextual_tasks_context_controller_impl.cc",
    "contextual_tasks_context_controller_impl.h",
  ]

  deps = [
    ":public",
    "//components/contextual_tasks/public",
    "//components/keyed_service/core",
  ]
}

if (!is_android) {
  source_set("ui") {
    sources = [
      "contextual_tasks_ui.cc",
      "contextual_tasks_ui.h",
    ]

    public_deps = [
      "//content/public/browser",
      "//content/public/common",
      "//ui/webui",
    ]

    deps = [
      "//base",
      "//chrome/browser/resources/contextual_tasks:resources",
      "//chrome/browser/ui/webui",
      "//components/contextual_tasks/public:feature_list",
    ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "contextual_tasks_context_controller_factory_unittest.cc",
    "contextual_tasks_context_controller_impl_unittest.cc",
    "contextual_tasks_service_factory_unittest.cc",
  ]

  deps = [
    ":contextual_tasks",
    ":internal",
    ":public",
    "//base",
    "//base/test:test_support",
    "//chrome/test:test_support",
    "//components/contextual_tasks/public",
    "//content/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
  ]
}