chrome/browser/accessibility/BUILD.gn

# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

if (!is_android) {
  source_set("test_support") {
    testonly = true
    public = [ "live_caption/live_caption_test_util.h" ]
    sources = [ "live_caption/live_caption_test_util.cc" ]

    public_deps = [
      "//base",
      "//chrome/browser/profiles:profile",
      "//chrome/test:test_support_ui",
    ]
    deps = [
      "//chrome/browser:browser_process",
      "//chrome/browser/ui",
      "//components/live_caption:constants",
      "//components/soda",
      "//components/soda:constants",
      "//components/sync_preferences",
      "//ui/accessibility",
    ]

    if (is_chromeos) {
      deps += [ "//ash/constants" ]
    }

    if (is_win) {
      public += [ "browser_test_with_ax_client.h" ]
      sources += [ "browser_test_with_ax_client.cc" ]
      public_deps += [
        "//chrome/test/accessibility/ax_client:launcher",
        "//chrome/test/accessibility/ax_client:mojom",
        "//mojo/public/cpp/bindings",
        "//ui/accessibility",
      ]
    }
  }
}

source_set("utils") {
  sources = [
    "pdf_ocr_metrics.cc",
    "pdf_ocr_metrics.h",
  ]

  deps = [
    "//base",
    "//ui/accessibility/platform",
  ]

  if (is_chromeos) {
    deps += [ "//chrome/browser/ash/accessibility" ]
  }
}