chrome/browser/resources/omnibox/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/closure_compiler/compile_js.gni")
import("//tools/grit/grit_rule.gni")

js_type_check("closure_compile") {
  deps = [
    ":omnibox",
  ]
}

js_library("omnibox") {
  deps = [
    ":omnibox_element",
    ":omnibox_input",
    ":omnibox_output",
    "//chrome/browser/ui/webui/omnibox:mojo_bindings_js_library_for_compile",
    "//ui/webui/resources/js:load_time_data",
  ]
}

js_library("omnibox_element") {
}

js_library("omnibox_input") {
}

js_library("omnibox_output") {
  deps = [
    "//ui/webui/resources/js:util",
  ]
  externs_list = [ "$externs_path/pending.js" ]
}

grit("resources") {
  source = "resources.grd"

  # The .grd contains references to generated files.
  source_is_generated = true
  outputs = [
    "grit/omnibox_resources.h",
    "omnibox_resources.pak",
  ]
  output_dir = "$root_gen_dir/chrome"
  depfile_dir = target_gen_dir
  grit_flags = [
    "-E",
    "root_gen_dir=" + rebase_path(root_gen_dir, root_build_dir),
  ]
  deps = [
    "//chrome/browser/ui/webui/omnibox:mojo_bindings_js",
  ]
}