chrome/browser/resources/chromeos/internet_config_dialog/BUILD.gn

# Copyright 2018 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ui/webui/resources/tools/build_webui.gni")

build_webui("build") {
  static_files = [ "internet_config_dialog_container.html" ]

  # Files holding a Polymer element definition AND have an equivalent .html file.
  web_component_files = [ "internet_config_dialog.ts" ]

  ts_definitions = [ "//tools/typescript/definitions/chrome_send.d.ts" ]
  ts_composite = true
  ts_deps = [
    "//ash/webui/common/resources:build_ts",
    "//ash/webui/common/resources/cr_elements:build_ts",
    "//third_party/polymer/v3_0:library",
    "//ui/webui/resources/cr_components/color_change_listener:build_ts",
    "//ui/webui/resources/js:build_ts",
    "//ui/webui/resources/mojo:build_ts",
  ]

  webui_context_type = "trusted"
  optimize = optimize_webui
  if (optimize) {
    optimize_webui_host = "internet-config-dialog"
    optimize_webui_in_files = [ "internet_config_dialog.js" ]
    optimize_webui_excludes = [
      "chrome://resources/ash/common/hotspot/cros_hotspot_config.mojom-webui.js",
      "chrome://resources/mojo/chromeos/services/network_config/public/mojom/cros_network_config.mojom-webui.js",
      "chrome://resources/mojo/chromeos/services/network_config/public/mojom/network_types.mojom-webui.js",
      "chrome://resources/mojo/services/network/public/mojom/ip_address.mojom-webui.js",
    ]
  }

  grd_prefix = "internet_config_dialog"
}