components/enterprise/client_certificates/core/BUILD.gn

# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//components/enterprise/buildflags/buildflags.gni")

assert(enterprise_client_certificates)

source_set("dm_server_client") {
  public = [ "dm_server_client.h" ]

  sources = [ "dm_server_client.cc" ]

  public_deps = [
    "//base",
    "//components/policy/core/common",
    "//components/policy/proto",
  ]

  deps = [ "//services/network/public/cpp" ]
}

source_set("cloud_management_delegate") {
  public = [ "cloud_management_delegate.h" ]

  public_deps = [ "//components/policy/core/common" ]
}

source_set("management_delegate") {
  public = [
    "browser_cloud_management_delegate.h",
    "profile_cloud_management_delegate.h",
  ]

  sources = [
    "browser_cloud_management_delegate.cc",
    "profile_cloud_management_delegate.cc",
  ]

  public_deps = [
    "//base",
    "//components/enterprise/core",
    "//components/policy/core/common",
    "//net",
  ]

  deps = [
    ":cloud_management_delegate",
    ":dm_server_client",
    "//components/enterprise",
    "//components/enterprise/browser/identifiers",
    "//components/policy/proto",
    "//components/prefs",
    "//third_party/boringssl",
  ]
}

source_set("core") {
  public = [
    "certificate_provisioning_service.h",
    "certificate_store.h",
    "client_certificates_service.h",
    "client_identity.h",
    "constants.h",
    "context_delegate.h",
    "dm_server_client.h",
    "ec_private_key.h",
    "ec_private_key_factory.h",
    "features.h",
    "key_upload_client.h",
    "leveldb_certificate_store.h",
    "metrics_util.h",
    "prefs.h",
    "prefs_certificate_store.h",
    "private_key.h",
    "private_key_factory.h",
    "private_key_types.h",
    "store_error.h",
    "unexportable_private_key.h",
    "unexportable_private_key_factory.h",
    "upload_client_error.h",
  ]

  sources = [
    "certificate_provisioning_service.cc",
    "certificate_store.cc",
    "client_certificates_service.cc",
    "client_identity.cc",
    "constants.cc",
    "ec_private_key.cc",
    "ec_private_key_factory.cc",
    "features.cc",
    "key_upload_client.cc",
    "leveldb_certificate_store.cc",
    "metrics_util.cc",
    "prefs.cc",
    "prefs_certificate_store.cc",
    "private_key.cc",
    "private_key_factory.cc",
    "private_key_types.cc",
    "ssl_client_cert_identity_wrapper.cc",
    "ssl_client_cert_identity_wrapper.h",
    "ssl_key_converter.cc",
    "ssl_key_converter.h",
    "store_error.cc",
    "unexportable_private_key.cc",
    "unexportable_private_key_factory.cc",
    "upload_client_error.cc",
  ]

  deps = [
    ":cloud_management_delegate",
    ":dm_server_client",
    "//components/enterprise/browser/identifiers",
    "//components/policy/core/common",
    "//components/policy/proto",
    "//components/prefs",
    "//net",
    "//services/network/public/cpp",
    "//third_party/boringssl",
  ]

  public_deps = [
    "//base",
    "//components/enterprise/client_certificates/proto:db_client_certs",
    "//components/enterprise/core",
    "//components/keyed_service/core",
    "//components/leveldb_proto",
    "//crypto",
  ]

  if (is_win) {
    public += [ "win/windows_software_private_key_factory.h" ]

    sources += [ "win/windows_software_private_key_factory.cc" ]
  }

  if (is_android) {
    public += [
      "android_private_key.h",
      "android_private_key_factory.h",
    ]

    sources += [
      "android_private_key.cc",
      "android_private_key_factory.cc",
    ]

    deps += [
      "//components/enterprise/client_certificates/android/browser_binding",
      "//third_party/jni_zero",
    ]
  }

  friend = [
    ":test_support",
    ":unit_tests",
  ]
}

source_set("test_support") {
  testonly = true
  sources = [
    "mock_certificate_provisioning_service.cc",
    "mock_certificate_provisioning_service.h",
    "mock_certificate_store.cc",
    "mock_certificate_store.h",
    "mock_cloud_management_delegate.cc",
    "mock_cloud_management_delegate.h",
    "mock_context_delegate.cc",
    "mock_context_delegate.h",
    "mock_dm_server_client.cc",
    "mock_dm_server_client.h",
    "mock_key_upload_client.cc",
    "mock_key_upload_client.h",
    "mock_private_key.cc",
    "mock_private_key.h",
    "mock_private_key_factory.cc",
    "mock_private_key_factory.h",
    "scoped_ssl_key_converter.cc",
    "scoped_ssl_key_converter.h",
  ]

  deps = [
    ":cloud_management_delegate",
    ":core",
    ":dm_server_client",
    "//components/leveldb_proto",
    "//components/policy/proto",
    "//crypto",
    "//crypto:test_support",
    "//net",
    "//net:test_support",
    "//testing/gmock",
    "//third_party/boringssl",
  ]

  if (is_android) {
    deps += [
      "//components/enterprise/client_certificates/android/browser_binding",
    ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "certificate_provisioning_service_unittest.cc",
    "client_certificates_service_unittest.cc",
    "dm_server_client_unittest.cc",
    "ec_private_key_factory_unittest.cc",
    "ec_private_key_unittest.cc",
    "key_upload_client_unittest.cc",
    "leveldb_certificate_store_unittest.cc",
    "prefs_certificate_store_unittest.cc",
    "private_key_factory_unittest.cc",
    "ssl_client_cert_identity_wrapper_unittest.cc",
    "unexportable_private_key_factory_unittest.cc",
    "unexportable_private_key_unittest.cc",
  ]

  if (is_win) {
    sources += [ "win/windows_software_private_key_factory_unittest.cc" ]
  }

  deps = [
    ":cloud_management_delegate",
    ":core",
    ":dm_server_client",
    ":management_delegate",
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//components/enterprise/client_certificates/proto:db_client_certs",
    "//components/leveldb_proto:test_support",
    "//components/policy/core/common",
    "//components/policy/core/common:test_support",
    "//components/prefs:test_support",
    "//content/test:test_support",
    "//crypto",
    "//crypto:test_support",
    "//net",
    "//net:test_support",
    "//services/network:test_support",
    "//services/network/public/cpp",
    "//testing/gmock",
    "//testing/gtest",
  ]

  if (is_android) {
    sources += [
      "android_private_key_factory_unittest.cc",
      "android_private_key_unittest.cc",
    ]

    deps += [
      "//components/enterprise/client_certificates/android/browser_binding",
      "//net",
    ]
  }
}