services/viz/privileged/mojom/gl/BUILD.gn

# Copyright 2017 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//build/config/sanitizers/sanitizers.gni")
import("//media/gpu/args.gni")
import("//mojo/public/tools/bindings/mojom.gni")

mojom("gl") {
  sources = [
    "context_lost_reason.mojom",
    "gpu_host.mojom",
    "gpu_service.mojom",
  ]

  parser_deps = [ "//components/viz/common:buildflags" ]

  deps = [ "//gpu/ipc/common:gmb_interface" ]

  public_deps = [
    "//gpu/ipc/common:interfaces",
    "//gpu/ipc/common:surface_handle",
    "//media/mojo/mojom",
    "//third_party/blink/public/mojom/tokens:tokens",
    "//ui/gfx/geometry/mojom",
    "//ui/gfx/mojom",
    "//ui/gl/mojom",
    "//url/mojom:url_mojom_gurl",
  ]
  if (is_chromeos_ash) {
    public_deps += [
      "//ash/components/arc/mojom:media",
      "//components/chromeos_camera/common",
    ]
  }

  if (is_win) {
    sources += [ "info_collection_gpu_service.mojom" ]
    public_deps += [ "//ui/gfx/mojom:dxgi_info" ]
  }

  enabled_features = []
  if (!is_android) {
    enabled_features += [ "is_not_android" ]
  }

  if (use_clang_profiling_inside_sandbox) {
    enabled_features += [ "use_clang_profiling_inside_sandbox" ]
  }

  if (is_chromeos_ash && (use_vaapi || use_v4l2_codec)) {
    enabled_features += [ "enable_arc_media" ]
  }

  cpp_typemaps = [
    {
      types = [
        {
          mojom = "viz.mojom.ContextLostReason"
          cpp = "::gpu::error::ContextLostReason"
        },
      ]
      traits_headers =
          [ "//services/viz/privileged/cpp/context_lost_reason_traits.h" ]
      traits_public_deps = [ "//gpu/command_buffer/common" ]
    },
    {
      types = [
        {
          mojom = "viz.mojom.OverlayStrategy"
          cpp = "::viz::OverlayStrategy"
        },
      ]
      traits_headers =
          [ "//services/viz/privileged/cpp/overlay_strategy_mojom_traits.h" ]
      traits_public_deps = [ "//components/viz/common" ]
    },
  ]
}