ios/chrome/browser/safe_mode/BUILD.gn

# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/public/provider/chrome/browser/build_config.gni")

source_set("safe_mode") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "safe_mode_crashing_modules_config.h",
    "safe_mode_crashing_modules_config.mm",
    "safe_mode_util.cc",
    "safe_mode_util.h",
  ]

  deps = [
    ":resources",
    "//base",
    ios_packed_resources_target,
  ]

  libs = [ "UIKit.framework" ]
}

bundle_data("resources") {
  visibility = [ ":safe_mode" ]
  sources = [
    "resources/SafeModeCrashingModules.plist",
  ]
  outputs = [
    "{{bundle_resources_dir}}/{{source_file_part}}",
  ]
}

source_set("unit_tests") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "safe_mode_util_unittest.cc",
  ]
  deps = [
    ":safe_mode",
    "//base",
    "//testing/gtest",
  ]
  libs = [ "UIKit.framework" ]
}