ui/base/mojom/BUILD.gn

# Copyright 2016 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

mojom("mojom") {
  generate_java = true
  sources = [
    "ui_base_types.mojom",
    "window_open_disposition.mojom",
  ]

  if (is_mac) {
    sources += [ "attributed_string.mojom" ]
    public_deps = [
      "//mojo/public/mojom/base",
      "//ui/gfx/range/mojom",
    ]
  }

  cpp_typemaps = [
    {
      types = [
        {
          mojom = "ui.mojom.DialogButton"
          cpp = "::ui::DialogButton"
        },
        {
          mojom = "ui.mojom.MenuSourceType"
          cpp = "::ui::MenuSourceType"
        },
        {
          mojom = "ui.mojom.ModalType"
          cpp = "::ui::ModalType"
        },
      ]
      traits_headers = [ "ui_base_types_mojom_traits.h" ]
      traits_public_deps = [ "//ui/base" ]
    },
    {
      types = [
        {
          mojom = "ui.mojom.WindowOpenDisposition"
          cpp = "::WindowOpenDisposition"
        },
      ]
      traits_headers = [ "window_open_disposition_mojom_traits.h" ]
      traits_public_deps = [ "//ui/base:types" ]
    },
  ]

  export_class_attribute_blink = "BLINK_PLATFORM_EXPORT"
  export_define_blink = "BLINK_PLATFORM_IMPLEMENTATION=1"
  export_header_blink = "third_party/blink/public/platform/web_common.h"
  webui_module_path = "chrome://resources/mojo/ui/base/mojom"

  # Generate WebUI bindings in TypeScript.
  use_typescript_sources = true

  # Generate legacy bindings for Blink.
  generate_legacy_js_bindings = true
}