chrome/browser/android/vr/BUILD.gn

# Copyright 2016 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//chrome/android/modules/buildflags.gni")
import("//chrome/common/features.gni")
import("//device/vr/buildflags/buildflags.gni")
import("//testing/test.gni")
import("//third_party/jni_zero/jni_zero.gni")

assert(enable_vr)

static_library("vr_android") {
  defines = []
  sources = []

  deps = [
    "//device/vr",
    "//device/vr:vr_base",
    "//device/vr:vr_util",
    "//device/vr/android:vr_android",
    "//device/vr/buildflags:buildflags",
  ]

  if (enable_arcore) {
    deps += [
      ":ar_jni_headers",
      "//device/vr/android/arcore",
    ]
  }

  public_deps = [ "//device/vr/public/mojom:isolated_xr_service" ]

  libs = [ "android" ]
}
if (enable_arcore) {
  generate_jni("ar_jni_headers") {
    sources = [ "//chrome/android/java/src/org/chromium/chrome/browser/vr/ArCompositorDelegateProviderImpl.java" ]
  }
}

if (enable_cardboard) {
  generate_jni("vr_jni_headers") {
    sources = [ "//chrome/android/java/src/org/chromium/chrome/browser/vr/VrCompositorDelegateProviderImpl.java" ]
  }
}

test("vr_android_unittests") {
  sources = [
    "arcore_device/arcore_device_unittest.cc",
    "arcore_device/fake_arcore.cc",
    "arcore_device/fake_arcore.h",
    "test/ar_test_suite.cc",
    "test/ar_test_suite.h",
    "test/run_all_unittests.cc",
  ]

  libs = [ "android" ]

  deps = [
    ":vr_android",
    "//base/test:test_support",
    "//chrome/browser",
    "//components/translate/core/language_detection:language_detection",
    "//components/webxr:webxr",
    "//device/vr:vr_fakes",
    "//device/vr/android:vr_android",
    "//device/vr/public/mojom:isolated_xr_service",
    "//mojo/core/embedder",
    "//mojo/public/cpp/bindings",
    "//services/network:test_support",
    "//testing/android/native_test:native_test_native_code",
    "//testing/gmock",
    "//testing/gtest",
    "//third_party/blink/public:blink",
    "//ui/android:ui_java",  # TODO: Remove once http://crbug.com/951419 is
                             # fixed!
  ]

  if (enable_arcore) {
    deps += [ "//device/vr/android/arcore" ]
  }
}