third_party/blink/common/BUILD.gn

# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/jumbo.gni")
import("//testing/test.gni")

jumbo_source_set("common") {
  visibility = [
    "//third_party/blink/*",
    ":*",
  ]

  defines = [ "BLINK_COMMON_IMPLEMENTATION=1" ]

  sources = [
    # NOTE: Please do not add public headers that need to be referenced from
    # outside WebKit, add them in public/common instead.
    "client_hints/client_hints.cc",
    "common_export.h",
    "device_memory/approximated_device_memory.cc",
    "feature_policy/feature_policy.cc",
    "frame/frame_policy.cc",
    "message_port/cloneable_message.cc",
    "message_port/cloneable_message_struct_traits.cc",
    "message_port/cloneable_message_struct_traits.h",
    "message_port/message_port_channel.cc",
    "message_port/transferable_message.cc",
    "message_port/transferable_message_struct_traits.cc",
    "message_port/transferable_message_struct_traits.h",
    "mime_util/mime_util.cc",
    "origin_manifest/origin_manifest.cc",
    "origin_trials/trial_token.cc",
    "origin_trials/trial_token_validator.cc",
  ]

  public_deps = [
    "//third_party/blink/public/common:headers",
  ]

  deps = [
    "//base",
    "//mojo/public/cpp/system",
    "//net",
  ]

  # iOS doesn't use and must not depend on //media
  if (!is_ios) {
    deps += [ "//media" ]
  }
}

test("blink_common_unittests") {
  visibility = [ "*" ]
  deps = [
    ":common_unittests_sources",
    "//third_party/blink/public/common",
  ]
}

jumbo_source_set("common_unittests_sources") {
  testonly = true

  sources = [
    "device_memory/approximated_device_memory_unittest.cc",
    "feature_policy/feature_policy_unittest.cc",
    "mime_util/mime_util_unittest.cc",
    "origin_manifest/origin_manifest_unittest.cc",
    "origin_trials/trial_token_unittest.cc",
    "origin_trials/trial_token_validator_unittest.cc",
    "test/run_all_unittests.cc",
  ]

  deps = [
    "//base",
    "//base/test:test_support",
    "//net",
    "//testing/gtest",
    "//third_party/blink/public/common:headers",
    "//third_party/boringssl",
  ]
}