ash/assistant/ui/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")
import("//chromeos/assistant/assistant.gni")

assert(is_chromeos)

component("constants") {
  output_name = "assistant_ui_constants"

  defines = [ "IS_ASSISTANT_UI_CONSTANTS_IMPL" ]

  sources = [
    "assistant_ui_constants.cc",
    "assistant_ui_constants.h",
  ]

  deps = [
    "//base",
    "//skia",
    "//ui/aura",
    "//ui/base",
    "//ui/gfx",
  ]
}

component("ui") {
  output_name = "assistant_ui"

  defines = [ "IS_ASSISTANT_UI_IMPL" ]

  sources = [
    "assistant_view_delegate.h",
    "assistant_view_ids.h",
    "assistant_web_container_view.cc",
    "assistant_web_container_view.h",
    "assistant_web_view_delegate.h",
    "base/assistant_button.cc",
    "base/assistant_button.h",
    "base/assistant_button_listener.h",
    "base/assistant_scroll_view.cc",
    "base/assistant_scroll_view.h",
    "base/stack_layout.cc",
    "base/stack_layout.h",
    "dialog_plate/mic_view.cc",
    "dialog_plate/mic_view.h",
    "logo_view/logo_view.cc",
    "logo_view/logo_view.h",
    "main_stage/animated_container_view.cc",
    "main_stage/animated_container_view.h",
    "main_stage/assistant_card_element_view.cc",
    "main_stage/assistant_card_element_view.h",
    "main_stage/assistant_error_element_view.cc",
    "main_stage/assistant_error_element_view.h",
    "main_stage/assistant_footer_view.cc",
    "main_stage/assistant_footer_view.h",
    "main_stage/assistant_onboarding_view.cc",
    "main_stage/assistant_onboarding_view.h",
    "main_stage/assistant_opt_in_view.cc",
    "main_stage/assistant_opt_in_view.h",
    "main_stage/assistant_progress_indicator.cc",
    "main_stage/assistant_progress_indicator.h",
    "main_stage/assistant_query_view.cc",
    "main_stage/assistant_query_view.h",
    "main_stage/assistant_text_element_view.cc",
    "main_stage/assistant_text_element_view.h",
    "main_stage/assistant_ui_element_view.cc",
    "main_stage/assistant_ui_element_view.h",
    "main_stage/assistant_ui_element_view_factory.cc",
    "main_stage/assistant_ui_element_view_factory.h",
    "main_stage/assistant_zero_state_view.cc",
    "main_stage/assistant_zero_state_view.h",
    "main_stage/element_animator.cc",
    "main_stage/element_animator.h",
    "main_stage/suggestion_chip_view.cc",
    "main_stage/suggestion_chip_view.h",
    "main_stage/suggestion_container_view.cc",
    "main_stage/suggestion_container_view.h",
    "main_stage/ui_element_container_view.cc",
    "main_stage/ui_element_container_view.h",
  ]

  deps = [
    "//ash/assistant/model",
    "//ash/assistant/ui:constants",
    "//ash/assistant/util",
    "//ash/keyboard/ui",
    "//ash/public/cpp",
    "//ash/public/cpp/vector_icons",
    "//ash/resources/vector_icons",
    "//ash/strings",
    "//base",
    "//chromeos/assistant:buildflags",
    "//chromeos/services/assistant/public/cpp",
    "//chromeos/services/assistant/public/mojom",
    "//services/content/public/cpp",
    "//ui/aura",
    "//ui/compositor",
    "//ui/gfx",
    "//ui/views",
    "//ui/views/window/vector_icons",
    "//ui/wm",
  ]

  if (enable_cros_libassistant) {
    sources += [
      "logo_view/logo_view_impl.cc",
      "logo_view/logo_view_impl.h",
      "logo_view/shape/mic_part_shape.cc",
      "logo_view/shape/mic_part_shape.h",
      "logo_view/shape/shape.cc",
      "logo_view/shape/shape.h",
    ]

    deps += [ "//chromeos/assistant/internal/logo_view" ]
  }
}