ios/chrome/browser/ui/toolbar/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("toolbar") {
  configs += [ "//build/config/compiler:enable_arc" ]
  sources = [
    "legacy_toolbar_coordinator.h",
    "legacy_toolbar_coordinator.mm",
    "legacy_toolbar_view.h",
    "legacy_toolbar_view.mm",
    "new_tab_button.h",
    "new_tab_button.mm",
    "toolbar_adapter.h",
    "toolbar_adapter.mm",
    "toolbar_controller+protected.h",
    "toolbar_controller.h",
    "toolbar_controller.mm",
    "toolbar_model_delegate_ios.h",
    "toolbar_model_delegate_ios.mm",
    "toolbar_model_impl_ios.h",
    "toolbar_model_impl_ios.mm",
    "toolbar_model_ios.h",
    "toolbar_view_delegate.h",
    "tools_menu_button_observer_bridge.h",
    "tools_menu_button_observer_bridge.mm",
    "web_toolbar_controller.h",
    "web_toolbar_controller.mm",
    "web_toolbar_delegate.h",
  ]
  deps = [
    ":resource_macros",
    ":toolbar_ui",
    "public",
    "public:toolbar_base_feature",
    "resources:collapse",
    "resources:collapse_incognito",
    "resources:collapse_pressed",
    "resources:collapse_pressed_incognito",
    "resources:incognito_marker_typing",
    "resources:toolbar_dark_newtab",
    "resources:toolbar_dark_newtab_active",
    "resources:toolbar_dark_newtab_incognito",
    "resources:toolbar_dark_newtab_incognito_active",
    "//base",
    "//base:i18n",
    "//components/bookmarks/browser",
    "//components/google/core/browser",
    "//components/omnibox/browser",
    "//components/prefs",
    "//components/reading_list/core",
    "//components/reading_list/ios",
    "//components/search_engines",
    "//components/strings",
    "//components/toolbar",
    "//ios/chrome/app/strings",
    "//ios/chrome/app/theme",
    "//ios/chrome/browser",
    "//ios/chrome/browser/autocomplete",
    "//ios/chrome/browser/bookmarks",
    "//ios/chrome/browser/browser_state",
    "//ios/chrome/browser/drag_and_drop",
    "//ios/chrome/browser/reading_list",
    "//ios/chrome/browser/search_engines",
    "//ios/chrome/browser/ssl",
    "//ios/chrome/browser/tabs",
    "//ios/chrome/browser/ui",
    "//ios/chrome/browser/ui/activity_services/requirements",
    "//ios/chrome/browser/ui/bubble",
    "//ios/chrome/browser/ui/colors",
    "//ios/chrome/browser/ui/commands",
    "//ios/chrome/browser/ui/coordinators:chrome_coordinators",
    "//ios/chrome/browser/ui/fancy_ui",
    "//ios/chrome/browser/ui/fullscreen",
    "//ios/chrome/browser/ui/fullscreen:new_fullscreen",
    "//ios/chrome/browser/ui/fullscreen:new_fullscreen_ui",
    "//ios/chrome/browser/ui/history",
    "//ios/chrome/browser/ui/history_popup/requirements",
    "//ios/chrome/browser/ui/image_util",
    "//ios/chrome/browser/ui/keyboard",
    "//ios/chrome/browser/ui/location_bar",
    "//ios/chrome/browser/ui/ntp",
    "//ios/chrome/browser/ui/omnibox",
    "//ios/chrome/browser/ui/omnibox/popup",
    "//ios/chrome/browser/ui/popup_menu",
    "//ios/chrome/browser/ui/qr_scanner/requirements",
    "//ios/chrome/browser/ui/toolbar/clean:toolbar",
    "//ios/chrome/browser/ui/toolbar/clean:toolbar_components_ui",
    "//ios/chrome/browser/ui/toolbar/clean:toolbar_ui",
    "//ios/chrome/browser/ui/toolbar/keyboard_assist",
    "//ios/chrome/browser/ui/tools_menu",
    "//ios/chrome/browser/ui/tools_menu:configuration",
    "//ios/chrome/browser/ui/tools_menu/public",
    "//ios/chrome/browser/ui/util",
    "//ios/chrome/browser/ui/voice",
    "//ios/chrome/browser/web_state_list",
    "//ios/chrome/common",
    "//ios/public/provider/chrome/browser",
    "//ios/public/provider/chrome/browser/images",
    "//ios/public/provider/chrome/browser/voice",
    "//ios/third_party/material_components_ios",
    "//ios/third_party/material_roboto_font_loader_ios",
    "//ios/web",
    "//net",
    "//ui/base",

    # Fake dependencies to break cycles
    "//ios/chrome/browser/ui/ntp",
    "//ios/chrome/browser/ui/side_swipe",
  ]
  public_deps = [
    "//ios/chrome/browser/ui/omnibox:omnibox_internal",
  ]
  allow_circular_includes_from = [
    "//ios/chrome/browser/ui/side_swipe",
    "//ios/chrome/browser/ui/toolbar/clean:toolbar",
    "//ios/chrome/browser/ui/ntp",
    "//ios/chrome/browser/ui/location_bar",
  ]
  libs = [
    "CoreLocation.framework",
    "UIKit.framework",
  ]
}

source_set("toolbar_ui") {
  sources = [
    "legacy_toolbar_ui_updater.h",
    "legacy_toolbar_ui_updater.mm",
    "toolbar_owner.h",
    "toolbar_snapshot_providing.h",
    "toolbar_ui.h",
    "toolbar_ui.mm",
  ]
  deps = [
    "//base",
    "//ios/chrome/browser/ui:ui_util",
    "//ios/chrome/browser/web_state_list",
    "//ios/web",
  ]
  configs += [ "//build/config/compiler:enable_arc" ]
  libs = [ "UIKit.framework" ]
}

source_set("toolbar_ui_broadcasting_util") {
  sources = [
    "toolbar_ui_broadcasting_util.h",
    "toolbar_ui_broadcasting_util.mm",
  ]
  deps = [
    ":toolbar_ui",
    "//ios/chrome/browser/ui/broadcaster",
  ]
  configs += [ "//build/config/compiler:enable_arc" ]
}

source_set("feature") {
  sources = [
    "toolbar_private_base_feature.h",
    "toolbar_private_base_feature.mm",
  ]
  deps = [
    "//base",
  ]
  configs += [ "//build/config/compiler:enable_arc" ]
}

source_set("resource_macros") {
  sources = [
    "toolbar_resource_macros.h",
  ]
  deps = [
    "//ios/chrome/app/theme",
  ]
}

source_set("test_support") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "test_toolbar_model_ios.h",
    "test_toolbar_model_ios.mm",
    "web_toolbar_controller_private.h",
  ]
  deps = [
    ":toolbar",
    "//base",
    "//components/toolbar",
    "//components/toolbar:test_support",
    "//ios/chrome/browser/tabs",
    "//ios/web/public/test/fakes",
  ]
}

source_set("unit_tests") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "legacy_toolbar_ui_updater_unittest.mm",
    "toolbar_controller_unittest.mm",
    "toolbar_model_impl_ios_unittest.mm",
    "toolbar_ui_broadcasting_util_unittest.mm",
    "web_toolbar_controller_unittest.mm",
  ]
  deps = [
    ":test_support",
    ":toolbar",
    ":toolbar_ui",
    ":toolbar_ui_broadcasting_util",
    "//base",
    "//components/bookmarks/browser",
    "//components/bookmarks/test",
    "//components/toolbar:test_support",
    "//ios/chrome/browser",
    "//ios/chrome/browser/bookmarks",
    "//ios/chrome/browser/browser_state:test_support",
    "//ios/chrome/browser/tabs",
    "//ios/chrome/browser/ui",
    "//ios/chrome/browser/ui/broadcaster",
    "//ios/chrome/browser/ui/toolbar/test",
    "//ios/chrome/browser/web_state_list",
    "//ios/chrome/browser/web_state_list:test_support",
    "//ios/chrome/test:test_support",
    "//ios/testing:ocmock_support",
    "//ios/web/public/test",
    "//ios/web/public/test/fakes",
    "//testing/gtest",
    "//third_party/ocmock",
  ]
}

source_set("eg_tests") {
  configs += [ "//build/config/compiler:enable_arc" ]
  testonly = true
  sources = [
    "toolbar_egtest.mm",
  ]

  deps = [
    ":toolbar",
    "//base",
    "//components/strings",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/ui",
    "//ios/chrome/browser/ui/commands",
    "//ios/chrome/browser/ui/content_suggestions:content_suggestions_constant",
    "//ios/chrome/browser/ui/ntp:ntp_controller",
    "//ios/chrome/browser/ui/ntp:ntp_internal",
    "//ios/chrome/browser/ui/omnibox:omnibox_internal",
    "//ios/chrome/browser/ui/toolbar/clean:toolbar_ui",
    "//ios/chrome/browser/ui/tools_menu/public",
    "//ios/chrome/test/app:test_support",
    "//ios/chrome/test/earl_grey:test_support",
    "//ios/testing/earl_grey:earl_grey_support",
    "//ios/third_party/earl_grey:earl_grey+link",
    "//ios/web/public/test/http_server",
    "//ui/base",
  ]
  libs = [ "XCTest.framework" ]
}