components/breadcrumbs/core/BUILD.gn

# Copyright 2021 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("core") {
  sources = [
    "breadcrumb_manager.cc",
    "breadcrumb_manager.h",
    "breadcrumb_manager_keyed_service.cc",
    "breadcrumb_manager_keyed_service.h",
    "breadcrumb_manager_observer.h",
    "breadcrumb_persistent_storage_manager.cc",
    "breadcrumb_persistent_storage_manager.h",
    "breadcrumb_persistent_storage_util.cc",
    "breadcrumb_persistent_storage_util.h",
    "crash_reporter_breadcrumb_constants.h",
  ]

  deps = [
    "//base",
    "//components/keyed_service/core",
  ]
}

source_set("feature_flags") {
  sources = [
    "features.cc",
    "features.h",
  ]
  deps = [ "//base" ]
}

source_set("unit_tests") {
  testonly = true
  deps = [
    ":core",
    ":generate_not_user_triggered_actions",
    "//base/test:test_support",
    "//testing/gtest",
  ]

  sources = [
    "application_breadcrumbs_not_user_action_unittest.cc",
    "breadcrumb_manager_keyed_service_unittest.cc",
    "breadcrumb_manager_observer_unittest.cc",
    "breadcrumb_manager_unittest.cc",
    "breadcrumb_persistent_storage_util_unittest.cc",
  ]
}

action("generate_not_user_triggered_actions") {
  script = "generate_not_user_triggered_actions.py"
  sources = [ "//tools/metrics/actions/actions.xml" ]
  outputs = [ "$target_gen_dir/application_breadcrumbs_not_user_action.inc" ]
  args = [
    "--actions",
    rebase_path(sources[0], root_build_dir),
    "--output",
    rebase_path(outputs[0], root_build_dir),
  ]
}