components/segmentation_platform/embedder/default_model/BUILD.gn

# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

static_library("default_model") {
  sources = [
    "contextual_page_actions_model.cc",
    "contextual_page_actions_model.h",
    "cross_device_user_segment.cc",
    "cross_device_user_segment.h",
    "device_switcher_model.cc",
    "device_switcher_model.h",
    "device_switcher_result_dispatcher.cc",
    "device_switcher_result_dispatcher.h",
    "feed_user_segment.cc",
    "feed_user_segment.h",
    "low_user_engagement_model.cc",
    "low_user_engagement_model.h",
    "resume_heavy_user_model.cc",
    "resume_heavy_user_model.h",
    "search_user_model.cc",
    "search_user_model.h",
    "shopping_user_model.cc",
    "shopping_user_model.h",
  ]
  deps = [
    "//base",
    "//components/prefs:prefs",
    "//components/segmentation_platform/internal",
    "//components/segmentation_platform/internal/proto",
    "//components/segmentation_platform/public",
    "//components/sync/driver",
    "//ui/base",
  ]
  if (is_android) {
    sources += [
      "device_tier_segment.cc",
      "device_tier_segment.h",
      "frequent_feature_user_model.cc",
      "frequent_feature_user_model.h",
      "intentional_user_model.cc",
      "intentional_user_model.h",
      "power_user_segment.cc",
      "power_user_segment.h",
      "query_tiles_model.cc",
      "query_tiles_model.h",
      "tablet_productivity_user_model.cc",
      "tablet_productivity_user_model.h",
    ]
    deps += [ "//components/query_tiles:public" ]
  }
}

source_set("unit_tests") {
  testonly = true

  # IMPORTANT NOTE: When adding new tests, also remember to update the list of
  # tests in //components/segmentation_platform/components_unittests.filter
  sources = [
    "contextual_page_actions_model_unittest.cc",
    "cross_device_user_segment_unittest.cc",
    "device_switcher_model_unittest.cc",
    "device_switcher_result_dispatcher_unittest.cc",
    "feed_user_segment_unittest.cc",
    "low_user_engagement_model_unittest.cc",
    "resume_heavy_user_model_unittest.cc",
    "search_user_model_unittest.cc",
    "shopping_user_model_unittest.cc",
  ]

  if (is_android) {
    sources += [
      "device_tier_segment_unittest.cc",
      "frequent_feature_user_model_unittest.cc",
      "intentional_user_model_unittest.cc",
      "power_user_segment_unittest.cc",
      "query_tiles_model_unittest.cc",
      "tablet_productivity_user_model_unittest.cc",
    ]
  }

  deps = [
    ":default_model",
    ":default_model_test_base",
    "//base",
    "//base/test:test_support",
    "//components/prefs:test_support",
    "//components/segmentation_platform/internal",
    "//components/segmentation_platform/internal/proto",
    "//components/segmentation_platform/public:public",
    "//components/segmentation_platform/public:test_support",
    "//components/segmentation_platform/public/proto",
    "//components/sync:test_support",
    "//testing/gtest",
  ]
}

source_set("default_model_test_base") {
  testonly = true
  sources = [
    "default_model_test_base.cc",
    "default_model_test_base.h",
  ]

  deps = [
    ":default_model",
    "//base",
    "//base/test:test_support",
    "//components/segmentation_platform/internal",
    "//components/segmentation_platform/internal/proto",
    "//components/segmentation_platform/public",
    "//testing/gtest",
  ]
}