chrome/browser/ui/webui/BUILD.gn

# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//chromeos/dbus/config/use_real_dbus_clients.gni")
import("//components/metrics/generate_allowlist_from_histograms_file.gni")

generate_allowlist_from_histograms_file("webui_url_hashes") {
  namespace = "webui_metrics"
  input_xml_file = "//tools/metrics/histograms/enums.xml"
  tag = "enum"
  output_file = "webui_url_hashes.h"
  allow_list_name = "WebUIUrlHashes"
}

source_set("configs") {
  sources = [
    "chrome_untrusted_web_ui_configs.cc",
    "chrome_untrusted_web_ui_configs.h",
    "chrome_web_ui_configs.cc",
    "chrome_web_ui_configs.h",
  ]

  configs += [ "//build/config/compiler:wexit_time_destructors" ]

  deps = [
    "//chrome/browser/ui",
    "//chrome/browser/ui/webui",
    "//components/compose:buildflags",
    "//components/lens:buildflags",
    "//content/public/browser",
    "//extensions/buildflags:buildflags",
    "//printing/buildflags",
    "//skia",
    "//third_party/abseil-cpp:absl",
  ]

  if (is_win || is_mac || is_linux || is_chromeos) {
    deps += [
      "//chrome/browser/ui/lens",
      "//chrome/browser/ui/views/side_panel",
    ]
  }

  # Includes Ash Chrome and Lacros Chrome
  if (is_chromeos) {
    deps += [ "//chromeos/constants" ]
  }

  if (is_chromeos_ash) {
    deps += [ "//chrome/browser/ui/webui/ash/config" ]
  }
}

source_set("webui") {
  sources = [
    "webui_util.cc",
    "webui_util.h",
  ]

  sources += get_target_outputs(":webui_url_hashes")

  deps = [
    ":webui_url_hashes",
    "//base",
    "//content/public/browser",
    "//content/public/common",
    "//services/network/public/mojom",
    "//ui/base",
    "//ui/resources",
  ]
  if (is_chromeos_lacros) {
    deps += [ "//chromeos/startup" ]
  }
}